☰

NTP サーバーの統計を分析するプログラムはありますか?

tag-icon • tag-icon 12.04 ntp
NTP サーバーの統計を分析するプログラムはありますか?

私は Ubuntu 12.04 を実行しており、NTP サーバーも問題なく実行しています。2 台の Windows 7 ボックスで Meinberg NTP サーバーを実行し、関連するサーバー モニターを使用してサーバーの状態を追跡しています。

同様の Linux モニターはありますか? できれば、時計の動作などを表示できる GUI 付きのモニターが望ましいです。

答え1

質問に対する正確な回答ではありませんが、/var/log/ntp/loopstats を分析する gnuplot スクリプトを使用しているとおっしゃっていますね。私も同じことをしています。以下は私が使用しているスクリプトです。

誰かがもっと良いことをしているなら、私も興味があります。

#! /usr/bin/gnuplot
# Remember to check you have these lines in /etc/ntp.conf and that ntpd is actually running:
#    statsdir /var/log/ntpstats/
#    statistics loopstats peerstats clockstats
#    filegen loopstats file loopstats type day enable
#    filegen peerstats file peerstats type day enable
#    filegen clockstats file clockstats type day enable

# Resolution: fullscreen
set term x11 size `xrandr | awk '/\*/{sub(/x/,",");print $1; exit}'`
set grid
set bars 0.4
set y2tics
set y2range [0:]
set ytics nomirror
set xdata time
set timefmt "%s"
set format x "%T"
set title "NTP statistics"
set ylabel "Clock offset / Roundtrip delay (ms)"
set y2label "Frequency offset (seconds per day)"
set xlabel "Time of day"
local_time = `date +%s --utc -d "12:00:00 $(date +%z)"`
utc_time   = `date +%s --utc -d "12:00:00"`
localdifferencefromUTC = utc_time - local_time
timeoffsettoday = `date +%s --utc -d "today 0:00"` + localdifferencefromUTC
plot \
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($3*1000):($5*1000/2) t "Clock offset" w errorlines lt 1 lw 2 pt 187, \
  "/var/log/ntpstats/peerstats" u ($2+timeoffsettoday):($6*1000):($8*1000/2) t "Roundtrip delay" w errorbars lt 26 pt 26,\
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($4*0.0864):($6*0.0864/2) axes x1y2 t "Frequency offset" w errorline lt 7 pt 65,\
  0 w l lt -1
pause mouse close

答え2

ntp.orgは多くのリンクウェブサイト上の監視ツール

関連情報