アプリの起動時に Box SimpleShare の設定パネルを非表示にするにはどうすればよいですか?

Question

私はボックスシンプルシェアログイン時にアプリが起動するように設定されていますが、アプリはメニューバーにアイコンが読み込まれた直後に環境設定パネルを起動します。 システム環境設定 > ユーザとグループ > ログイン項目その動作は変わりません。

私はAppleScriptを作成し、アプリとして保存して起動しようとしました。ボックスシンプルシェアログイン時にアプリを起動し、設定パネルを非表示にしようとしましたが、期待どおりに動作しません。

set tApp to "Box SimpleShare"
tell application tApp to launch
tell application "System Events"
    set visible of process "Box SimpleShare" to false
end tell

これによりアプリは起動しますが、ボックスシンプルシェア設定パネル。これを行うための適切なコードは何でしょうか?

Answer 1

Boxの設定ウィンドウは特に永続的です。アプリケーションを起動するたびに表示されるだけでなく、アプリケーションが初期化シーケンスを完了する前に閉じると再び開きます。ただし、GUIスクリプトを使用すると、はこれを取り除くことは可能です。次のコードは、アプリケーションを起動し、設定ウィンドウがポップアップするのを待ってから、少し待ってから閉じます (初期化シーケンスを完了するため)。

property timeOutMax : 5
property timeOutStep : 1
property boxLoadDelay : 2

set boxApp to "Box SimpleShare"
tell application boxApp to launch
set timeOutCounter to 0
tell application "System Events"
    tell process boxApp
        repeat while (window 1 of it exists) is false and timeOutCounter is less than timeOutMax
            delay timeOutStep
            set timeOutCounter to timeOutCounter + timeOutStep
        end repeat
        if window 1 of it exists then
            delay boxLoadDelay
            click (button 1 of window 1 of it)
        end if
    end tell
end tell

システムでウィンドウが再度開く場合は、 の値を高く設定しますboxLoadDelay。また、アプリケーションが読み込まれる前にスクリプトがタイムアウトする場合は、 の値を調整しますtimeOutMax(timeOutStepタイムアウトしきい値をもっと高く設定する必要がある場合は、 も調整します)。