☰

Windows 7 のローカル エリア接続スイッチは再起動後に無効になります

tag-icon • tag-icon windows-7 home-networking
Windows 7 のローカル エリア接続スイッチは再起動後に無効になります

PC (Windows 7) をネットに接続したままにするには、助けが必要です。ローカル エリア接続を無効から有効に変更してネットに復帰する方法を見つけました。しかし、PC を起動または再起動すると、接続が無効に戻ります。設定を有効にしたままにするには、どうすればよいか知っている人はいませんか?

答え1

解決策としては、LAN を有効にするバッチ ファイルを作成し、システムの起動時にそれを実行するというものがあります。これは最善の方法ではありません。しかし、再インストールするよりは間違いなく優れています。

ステップ1 - devconを取得する

ここから devcon.exe をダウンロードしてください: http://download.microsoft.com/download/1/1/f/11f7dd10-272d-4cd2-896f-9ce67f3e0240/devcon.exe

devcon.exe をバッチ ファイルと同じディレクトリに配置します。

ステップ2 - アダプタ名を取得する

コントロール パネル > ネットワークと共有センターに移動します。 左側のペインでアダプターの設定の変更をクリックします。

問題のあるLAN接続を見つけて、アダプタ名を書き留めます。次のような名前です。Broadcom NetXtreme Gigabit Ethernet

あるいは、コマンドプロンプトでipconfig /all

LAN 接続を見つけて、その「説明」を書き留めます。説明はアダプタ名に他なりません。

ステップ3 - バッチファイル

アダプタ名がわかったら、それを次のバッチ ファイルに入力します。

@echo off
goto Start

rem Use this batch file to enable or disable a device
rem from the Command Prompt.

:Start
setlocal enabledelayedexpansion
set Adapter=<PUT YOUR ADAPTER NAME HERE>

if /i "%1"=="enable" goto go
if /i "%1"=="disable" goto go
echo Syntax: Device enable / disable
goto :eof

:go
set HWID=x
set count=0
set found=no

devcon hwids "PCI\*" > device.txt
for /F "tokens=*" %%* in (device.txt) do (
set /a count=!count! + 1
if /i "%%*"=="Name: %Adapter%" set found=yes& set count=1
if !found!==yes if !count!==3 set HWID=%%*
)
if %found%==yes (
echo HWID=!HWID!
devcon %1 "!HWID!"
) else (
echo Device "%Adapter%" not found.
)
endlocal
del device.txt

abc.bat として保存し、バッチ ファイルをテストします。

バッチを使用するための構文は次のとおりです。

abc.bat enable

動作する場合は、起動時に実行するようにスケジュールします。

関連情報