☰

3列で一意の値を見つける

tag-icon • tag-icon microsoft-excel-2010
3列で一意の値を見つける

Excel に 3 つの列があります。列 A、B、C で一意の値を見つけたいです。

それで：

  1. 列 A を調べて、列 B や列 C にない一意の値を見つけたいです。
  2. 列 B を調べて、列 A や列 C にない一意の値を見つけたいです。
  3. 列 C を見て、列 A や列 B にない一意の値を見つけたいです。

これは私が列Aに入力したものです

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

これは私が列Bに入力したものです

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

これはC列に入力したものです

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

これにより、3 つの列に重複した値が生成されますが、これらの値は一意である必要があります。おそらく、私はこれを非常に複雑にしているだけでしょう。これを解決する方法について何かアイデアはありますか?

表の例:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

この例では、各列に一意の番号が必要です。したがって、列 A では、列 B または C にない一意の値は = 1、4、5、6 です。列 B では、列 A または C にない一意の値は = 8、9、10 です。列 C では、列 B または C にない一意の値は = 11、12、13 です。これらの 3 つの数式に対して、列 D、E、F に数式を作成したいと思います。

1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

この例では、各列に一意の番号が必要です。したがって、列 A では、列 B または C にない一意の値は = 1、4、5、6 です。列 B では、列 A または C にない一意の値は = 8、9、10 です。列 C では、列 B または C にない一意の値は = 11、12、13 です。これらの 3 つの数式に対して、列 D、E、F に数式を作成したいと思います。

答え1

D1 では、次のような配列数式†を使用できます。

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

他の列の式も同様です。

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

そして、あなたのサンプルテーブルから、次のものを取得します。

ここに画像の説明を入力してください

ROW()数式が最初の行とは異なる行から始まる場合、数式が配置されている行に依存する が使用されるため、数式を少し変更する必要があります。

†注意: 数式を使用するには、Ctrl+ を押したままにして、数式を挿入した後にShiftを押す必要がありますEnter。

関連情報