☰

zsh プロンプトを vi モードで表示モードにする

tag-icon • tag-icon shell prompt zsh
zsh プロンプトを vi モードで表示モードにする

私はbindkey -v(bash ユーザーならset -o vizsh でも使えると思います) または vi(m) モードを使用しています。しかし、挿入モードかコマンド モードかを示す視覚的な手がかりがないのが気になります。プロンプトにモードを表示する方法を誰か知っていますか?

答え1

私は見つけたこれ経由す以下は基本的な例ですが、まだ自分用にカスタマイズ中です。

function zle-line-init zle-keymap-select {
    RPS1="${${KEYMAP/vicmd/-- NORMAL --}/(main|viins)/-- INSERT --}"
    RPS2=$RPS1
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

説明したいのですが、まだよく理解できていません

答え2

モードが変更されるたびに実行されるものは既に見つかりましたzle-keymap-select。これを使用して、端末がサポートするもの (およびもちろんモード インジケーターの表示に関する好み) に応じて、プロンプト以外の視覚インジケーターを設定できます。

標準があるterminfo 機能カーソルの形状を変更します。ただし、一部の端末では両方のモードで同じカーソルが表示されます。Xterm では、カーソルが見えにくくなると点滅します (これは、コマンド-bcライン引数またはcursorBlinkリソースで有効にする必要があります)。

zle-keymap-select () {
  case $KEYMAP in
    vicmd) print -rn -- $terminfo[cvvis];; # block cursor
    viins|main) print -rn -- $terminfo[cnorm];; # less visible cursor
  esac
}

いくつかの端末では、カーソルの色をprint -n '\e]12;pink\a'(色名で) またはprint -n '\e]12;#abcdef\a'(RGB指定で) で変更することもできます。これらの手順は、xtermのドキュメントのctlseqsファイル; 最近の端末エミュレータは通常 xterm をエミュレートしますが、すべての機能をサポートしているわけではない場合があります。

答え3

複数行のプロンプトでreset-promptを使用する際に問題が発生する場合は、https://stackoverflow.com/questions/3622943/zsh-vi-mode-status-line結局、私は次のことをやりました:

terminfo_down_sc=$terminfo[cud1]$terminfo[cuu1]$terminfo[sc]$terminfo[cud1]

function insert-mode () { echo "-- INSERT --" }
function normal-mode () { echo "-- NORMAL --" }

precmd () {
    # yes, I actually like to have a new line, then some stuff and then 
    # the input line
    print -rP "
[%D{%a, %d %b %Y, %H:%M:%S}] %n %{$fg[blue]%}%m%{$reset_color%}"

    # this is required for initial prompt and a problem I had with Ctrl+C or
    # Enter when in normal mode (a new line would come up in insert mode,
    # but normal mode would be indicated)
    PS1="%{$terminfo_down_sc$(insert-mode)$terminfo[rc]%}%~ $ "
}
function set-prompt () {
    case ${KEYMAP} in
      (vicmd)      VI_MODE="$(normal-mode)" ;;
      (main|viins) VI_MODE="$(insert-mode)" ;;
      (*)          VI_MODE="$(insert-mode)" ;;
    esac
    PS1="%{$terminfo_down_sc$VI_MODE$terminfo[rc]%}%~ $ "
}

function zle-line-init zle-keymap-select {
    set-prompt
    zle reset-prompt
}
preexec () { print -rn -- $terminfo[el]; }

zle -N zle-line-init
zle -N zle-keymap-select

答え4

これは、zsh でカーソルを「ブロック」と「ビーム」の形状間で変更するために使用するものです。

（テスト済みシロアリ、gnomeターミナルそしてメイト端子）

# vim mode config
# ---------------

# Activate vim mode.
bindkey -v

# Remove mode switching delay.
KEYTIMEOUT=5

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'

  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select

# Use beam shape cursor on startup.
echo -ne '\e[5 q'

# Use beam shape cursor for each new prompt.
preexec() {
   echo -ne '\e[5 q'
}

関連情報