☰

Excel: 複数のワークブックのセル情報を検索する方法

tag-icon • tag-icon vba microsoft-excel-2013
Excel: 複数のワークブックのセル情報を検索する方法

現在、当社は顧客から Excel で記入された電子フォームを受け取っているため、ワークブックが詰まったフォルダーがあります。

各ワークブックには複数のシートがあります。

「Sheet3 の J8:Y8」と「Sheet 4 の G8:AC8」の範囲が入力されているかどうかを確認するために、各ワークブックを検索する必要があります。これらの範囲はさらに精査する必要がありますが、これらのシートが完了しているワークブックはごくわずかです。

また、各ワークブックにはまったく異なる名前が付けられています。

私はオンラインでこのコード (以下) を見つけましたが、これは原理的には必要なことを行います。ただし、このコードはワークブックのすべてのシートで特定の「値」を検索します。

Sub SearchFolders()
Dim fso As Object
Dim fld As Object
Dim strSearch As String
Dim strPath As String
Dim strFile As String
Dim wOut As Worksheet
Dim wbk As Workbook
Dim wks As Worksheet
Dim lRow As Long
Dim rFound As Range
Dim strFirstAddress As String
      

On Error GoTo ErrHandler
Application.ScreenUpdating = False


'Change as desired
strPath = "c:\MyFolder"
strSearch = "Specific text"

Set wOut = Worksheets.Add
lRow = 1
With wOut
    .Cells(lRow, 1) = "Workbook"
    .Cells(lRow, 2) = "Worksheet"
    .Cells(lRow, 3) = "Cell"
    .Cells(lRow, 4) = "Text in Cell"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set fld = fso.GetFolder(strPath)

    strFile = Dir(strPath & "\*.xls*")
    Do While strFile <> ""
        Set wbk = Workbooks.Open _
          (Filename:=strPath & "\" & strFile, _
          UpdateLinks:=0, _
          ReadOnly:=True, _
          AddToMRU:=False)

        For Each wks In wbk.Worksheets
            Set rFound = wks.UsedRange.Find(strSearch)
            If Not rFound Is Nothing Then
                strFirstAddress = rFound.Address
            End If
            Do
                If rFound Is Nothing Then
                     lRow = lRow + 1
                    .Cells(lRow, 1) = wbk.Name
                    .Cells(lRow, 2) = wks.Name
                    .Cells(lRow, 3) = rFound.Address
                    .Cells(lRow, 4) = rFound.Value
Else
Exit Do

                End If
                Set rFound = wks.Cells.FindNext(After:=rFound)
            Loop While strFirstAddress <> rFound.Address
        Next

            wbk.Close (False)
            strFile = Dir
        Loop
        .Columns("A:D").EntireColumn.AutoFit
    End With
    MsgBox "Done"

ExitHandler:
    Set wOut = Nothing
    Set wks = Nothing
    Set wbk = Nothing
    Set fld = Nothing
    Set fso = Nothing
    Application.ScreenUpdating = True
    Exit Sub

ErrHandler:
    MsgBox Err.Description, vbExclamation
    Resume ExitHandler
End Sub

答え1

このコードは次のように動作します。

  1. 好きな場所で新しいワークブックを開きます。
  2. VBAコードをマクロに貼り付けます

  3. シート 1 のセル A1 に、ワークブックのフォルダーへのパスを入力します。例:C:\users\yourname\folder\

  4. セル A2 の最初の範囲の例:J8:Y8セル B2 のシート名:Sheet3

  5. セル A3 の 2 番目の範囲の例:G8:AC8セル B3 のシート名:Sheet4

このコードの最も優れた点は、検索する範囲やシートがさらにある場合に、次の行に追加できることです。

次のようになります:

ここに画像の説明を入力してください

さて、マクロを実行すると、実行後に結果が表示されます。シート2ファイル名と各範囲の空白セルの数が表示されます。

Sub foldersearch()
    Dim wbk As Workbook
    Dim wbk1 As Workbook
    Dim wks As Worksheet
    Dim wks2 As Worksheet
    Dim totaltime As Long
    Dim dtDuration As Date
    Set wbk = ThisWorkbook
    Set wks = wbk.Sheets(1)
    Set wks2 = wbk.Sheets(2)
    starttime = Now()
    wks2.Cells.ClearContents
    dirPath = wks.Cells(1, 1)
    file = Dir(dirPath)
    rowscounter = 0
    Application.ScreenUpdating = False
    While (file <> "")
        If InStr(file, "xls") > 0 Then
            rowscounter = rowscounter + 1
            totalpath = dirPath & file
            Set wbk1 = Workbooks.Open(totalpath, , True)
            rangelist = True
            i = 2
            columnscounter = 2
            While rangelist = True
                thenewrango = wks.Cells(i, 1)
                thenewsheet = wks.Cells(i, 2)
                emptycount = workbooksearch(wbk1, thenewsheet, thenewrango)
                wks2.Cells(rowscounter, 1) = file
                wks2.Cells(rowscounter, columnscounter) = emptycount
                i = i + 1
                columnscounter = columnscounter + 1
                If wks.Cells(i, 1) = "" Then
                    rangelist = False
                End If
            Wend
            wbk1.Close (False)
        End If
        file = Dir
    Wend
    Application.ScreenUpdating = True
    endtime = Now()
    totaltime = DateDiff("s", starttime, endtime)
    a = MsgBox("Finished in" & vbCrLf & totaltime & " seconds", vbOKOnly)
End Sub
Function workbooksearch(wbk1 As Workbook, wksname As Variant, rango As Variant)
    Dim wks1 As Worksheet
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbk1.Sheets(wksname)
    Set wks1 = wbk1.Worksheets(wksname)
    emptycount = 0
    For Each c In wks1.Range(rango)
        If c.Value = "" Then
            emptycount = emptycount + 1
        End If
    Next c
    workbooksearch = emptycount
    Exit Function
HandleError:
    workbooksearch = "N/A"
End Function

関連情報