☰

Excel - あるワークブックから別のワークブックにすべてのシートをコピーする方法

tag-icon • tag-icon vba microsoft-excel-2013
Excel - あるワークブックから別のワークブックにすべてのシートをコピーする方法

「test」というワークブックがあります。「estimate」というワークブックのすべてのシートを「test」にコピーしたいのですが、「estimate」から「test」にコピーできるシートのリストを作成する方法がわかりません。VBA でそれを行う方法はありますか?

答え1

考慮する：

Sub dural()
   Dim b1 As Workbook, b2 As Workbook
   Dim sh As Worksheet

   Workbooks.Open Filename:="C:\TestFolder\test.xls"
   Set b1 = ActiveWorkbook
   Workbooks.Open Filename:="C:\TestFolder\estimate.xls"
   Set b2 = ActiveWorkbook

   For Each sh In b2.Sheets
      sh.Copy after:=b1.Sheets(b1.Sheets.Count)
   Next sh
End Sub

答え2

こうするとリストされます

Sub list()
Dim wbEstimate As Workbook
Set wbEstimate = ThisWorkbook
Dim wsList As Worksheet
Dim numSheets As Integer
numSheets = wbEstimate.Sheets.Count
Worksheets.Add(After:=Worksheets(numSheets)).Name = "list"
Set wsList = Worksheets("list")
Dim i As Integer
i = 1

For Each Sheet In wbEstimate.Worksheets
    wsList.Cells(i, 1) = Sheet.Name
    i = i + 1
Next
End Sub

そしてこれは彼らを模倣するべきである両方開いている場合

Sub list()
Dim wbEstimate As Workbook
Set wbEstimate = ThisWorkbook
Dim wbTest As Workbook
Set wbTest = Workbooks("test.xlsx")

For Each Sheet In wbEstimate.Sheets
    Sheet.Copy after:=wbTest.Sheets(wbTest.Sheets.Count)
Next
End Sub

シートをコピーする前にテスト用のシートを開く必要がある場合は、次のようにします。

Sub list()
Dim wbEstimate As Workbook
Set wbEstimate = ThisWorkbook
Dim wbTest As Workbook
Set wbTest = Workbooks.Open("C:\Users\path\to\test.xlsx")

For Each Sheet In wbEstimate.Sheets
    Sheet.Copy after:=wbTest.Sheets(wbTest.Sheets.Count)
Next
End Sub

関連情報