☰

Win 10 から 1 つのドライブを削除する

tag-icon • tag-icon windows-10 onedrive
Win 10 から 1 つのドライブを削除する

私は Amazon Cloud を使用していますが、コンピューターで One Drive をアクティブにしたくないと思っています。また、クリーンな観点から、アイコンなども削除したいと思っています。しかし、(当然ですが) MSFT ではこれが簡単な作業ではないようです。誰かこれを行う方法を知っていますか? レジストリでしょうか?

答え1

私は見つけたドイツのウェブサイト上のスクリプトこのテキストを txt ファイルにコピーし、名前を RemoveOneDrive.cmd に変更して、管理者としてこのコマンドを実行します。

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

これにより、まず OneDrive プロセスが強制終了され、削除されて、Windows エクスプローラーからエントリが削除されます。

関連情報