☰

マルチパート RAR を抽出し、抽出時に部分を削除します。

tag-icon • tag-icon windows compression rar
マルチパート RAR を抽出し、抽出時に部分を削除します。

80GB のマルチパート rar を解凍しました。空き容量は 5GB あり、rar アーカイブの各パートは 2GB です。

私が求めているのは、1 つの部分を抽出し、それを削除し、次の部分を抽出する、というようにして、抽出プロセスで最大 5 GB を追加使用し、すべてのディスク領域を使い果たさないようにすることです。

答え1

重要：

  • このスクリプト意思最終結果に関係なく、抽出が完了した部分を削除するため、欠落または破損した部分のためにプロセスが停止した場合、最初からやり直すことはできません。
  • メモ帳を開いて次のコードを貼り付けて保存します。_unrar.vbsrar ファイルと同じフォルダーに保存します。
  • セットUnRAR_フルパス、最初の部分そしてターゲットフォルダ引用符を必ず残してください。

スクリプト：

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

オプション 1:静けさ

実行する_unrar.vbsファイルをダブルクリックして

オプション2:推奨

削除する'の初めから

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

cmdを開き、フォルダに直接移動して入力します「cscript _unrar.vbs」

  • 使用してWScript.Echoそれなしスクリプト迷惑なメッセージボックスが多すぎる

このスクリプトは、UnRAR.exe の Stdout を読み取ることで動作します。

編集

スクリプトが改善され、任意の名前構造と最大 9999 個のパーツ数で自動的に動作し、先頭にゼロが含まれないレガシー アーカイブで動作できるようになりました。

関連情報