☰

最初の差異の後に diff を停止

tag-icon • tag-icon linux diff comparison
最初の差異の後に diff を停止

2つのファイルに対してを実行しdiff、最初の相違点を見つけたら停止したいです。diffもちろん を介してコマンドを実行する必要はありませんが、最初の相違点が見つかり報告されたら実際のコマンドを停止する必要があります。とても大きなファイルで、完全に一致することを期待していますが、違いが見つかった場合はその違いが何であったかを知りたいので、、、diff -qはdiff ... |head -1適しcmpていません。また、ファイルが非常に大きいため、メモリを使い果たさないものが望ましいです。現在の問題には必要ありませんが、最初の（ユーザー指定の）n 個の違いに機能するソリューションや、空白の違いを無視できるソリューションにはボーナスポイントが付きます。

答え1

cmp最初の違いで停止します。

% cat foo
foo
bar
baz
---
foo
bar
baz
% cat bar
foo
bar
baz
---
foo+
bar+
baz+
% cmp foo bar
foo bar differ: byte 20, line 5
%

さまざまな行を印刷するために、スクリプトをラップすることができます。

#! /bin/bash
line=$(cmp "$1" "$2" | awk '{print $NF}')
if [ ! -z $line ]; then
    awk -v file="$1" -v line=$line 'NR==line{print "In file "file": "$0; exit}' "$1"
    awk -v file="$2" -v line=$line 'NR==line{print "In file "file": "$0; exit}' "$2"
 fi

% ./script.sh foo bar
In file foo: foo
In file bar: foo+

コストの一部は AWK コマンドに移行されましたが、両方のファイルを完全にチェックするよりも大幅に高速になるはずです。

答え2

私はこれを些細なケースでテストしましたが、フィールドテストはあなたにお任せします。

$ cat f1
l1
l21 l22       l23  l24


l3
l4x
l5


$ cat f2
l1
l21 l22       l23

l3
l4y
l5



$ cat awkdiff.awk


BEGIN {
   maxdiff = 5
   ignoreemptylines = 1
   whitespaceaware = 1

   if (whitespaceaware) {
      emptypattern = "^[[:space:]]*$"
   } else {
      emptypattern = "^$"
      FS=""
   }

   f1 = ARGV[1]
   f2 = ARGV[2]

   rc1=rc2=1
   while( (rc1>0 && rc2>0 && diff<maxdiff)  ) {
      rc1 = getline l1 < f1 ; ++nr1
      rc2 = getline l2 < f2 ; ++nr2

      if (ignoreemptylines) {
         while ( l1 ~ emptypattern   &&  rc1>0) {
            rc1 = getline l1 < f1 ; ++nr1
         }

         while ( l2 ~ emptypattern  &&  rc2>0) {
            rc2 = getline l2 < f2 ; ++nr2
         }
      }


      if ( rc1>0 && rc2>0) {
         nf1 = split( l1, a1)
         nf2 = split( l2, a2)

         if ( nf1 <= nf2) {
            nfmin = nf1
         } else {
            nfmin = nf2
         }

         founddiff = 0
         for (i=1; i<=nfmin; ++i) {
            if ( a2[i]"" != a1[i]"") {
               printf "%d:%d:{%s} != %d:%d:{%s}\n", \
                  nr1, nf1, a1[i], nr2, nf2, a2[i]
               founddiff=1
               ++diff
               break
            }
         }

         if ( !founddiff  &&  nf1 != nf2) {
            if ( nf1 > nf2)
               printf "%d:%d:{%s} != %d:EOL\n", nr1, nfmin+1, a1[nfmin+1], nr2
            else
               printf "%d:EOL != %d:%d:{%s}\n", nr1, nr2, nfmin+1, a2[nfmin+1]
            ++diff
         }
      } else {
         if ( rc1 == -1 && rc2 == -1) {
            print "IO error"
         } else if ( rc1 == 1 && rc2 == 0) {
            print "%d:%s != EOL\n", nr1, l1
         } else if ( rc1 == 0 && rc2 == 1) {
            printf "EOL != %d:%s\n", nr2, l2
         }
      }
   }
}


$ awk -f awkdiff.awk  /tmp/f1 /tmp/f2
2:4:{l24} != 2:EOL
6:1:{l4x} != 5:1:{l4y}

maxdiff = N: 比較を停止する最大差異数を設定します

ignoreemptylines = 1|0: 比較時に空行を無視するかどうかを指定します

whitespaceaware = 1|0: 比較を単語単位（連続する空白は等しいと仮定）で行うか行単位で行うかを指定します

関連情報