重複の Excel 式

Question

列 C にある正確なデータを作成するために必要な数式を教えていただけませんか。

列 B の重複セルでは、列 A の SKU が列 C にコピーされます。

うまく説明できたと思います!!

Answer 1

Office 365 Excel をお持ちでない場合は、UDF が必要になります。次のコードをワークブックに添付されたモジュールに入力します。

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then 
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
    Else
        TEXTJOIN = ""
    End IF
End Function

次に、次の配列数式で目的の動作を実行します。

=TEXTJOIN(" | ",TRUE,IF($A$2:$A$11<>A2,IF($B$2:$B$11=B2,$A$2:$A$11,""),""))

配列数式なので、編集モードを終了するときに Enter キーではなく Ctrl + Shift + Enter キーを押して確定する必要があります。正しく実行すると、Excel によって{}数式が囲まれます。

---

Office 365 Excel をお持ちの場合は、上記の数式を配列数式として使用するだけで、UDF は必要ありません。

UDF は TEXTJOIN の機能を模倣します。