☰

ディスク上のすべてのファイルを一覧表示するバッチ スクリプト

tag-icon • tag-icon windows command-line batch
ディスク上のすべてのファイルを一覧表示するバッチ スクリプト

すべてを 1 つのディスク ファイルにリストする小さなバッチ ファイルを作成したいと思います。コマンドは次のとおりです。

TREE L: / F / A> List.txt

しかし、処理するドライブ文字をユーザーに入力させ、結果を名前と現在の日付とともにファイルに格納したいと思います。例:

C:\> makelist.bat
Please, insert the drive letter: L
Done!

結果は、たとえばという名前のファイルに入力しList_2017-03-13.txt、デスクトップに移動する必要があります。

スクリプトを作成するにはどのようなコマンドを使用すればよいですか?

答え1

次のバッチはwmicを使用して

  • ロケール/ユーザー設定に依存しない日付を取得する
  • 利用可能なドライブ文字のリストを取得する
  • 文字を選択するオプション
:: makelist.bat
@Echo off&SetLocal EnableExtensions EnableDelayedExpansion
set Started=%date% %time%
:: get locale/user-settings independent date
for /f "delims=." %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set "DT=%%A"
Set MyDate=%DT:~0,4%-%DT:~4,2%-%DT:~6,2%

:: gather available drives
Set "Drives="
FOr /f "delims=:" %%A in (
  'Wmic logicaldisk get name^|findstr "^[A-Z]:"'
) DO Set "Drives=!Drives!%%A"

:: choose drive letter
Choice /C %Drives% /M "Select drive letter for tree"
Set /A "Inp=%Errorlevel%,Pnt=Inp-1"
IF %Inp% equ 0   Echo aborted & pause & exit /B 1
If %Inp% equ 255 Echo aborted & pause & exit /B 1
Set "Drive=!Drives:~%Pnt%,1!"

:: do the tree 
Echo %Started% Tree started
Echo Tree %Drive%:\ /F /A  "%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
     Tree %Drive%:\ /F /A >"%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
Echo %date% %time% done
timeout -1

サンプルダイアログ:

Select drive letter for tree [C,D,E,G,H,K,M,N,P,Q,R,T,U,V,W,X,Z]?H
2017-03-13 14:17:05,45 Tree started
Tree H:\ /F /A "C:\Users\UserName\Desktop\Tree_H_2017-03-13.txt"
2017-03-13 14:17:13,70 done

Drücken Sie eine beliebige Taste, um den Vorgang fortzusetzen...

答え2

tree2txt.bat:

@tree %1 / F / A > Tree_%1_%date.TxT

使用法： tree2txt X:

結果: ドライブ X:\ のツリーが Tree_X_20170313.TxT というファイルに作成されます

日付の出力形式は、ローカルの日付形式設定 (yyyy-mm-dd およびその他の形式) に依存することに注意してください。

関連情報