☰

Microsoft Excel、1 つのセルに複数の数式

tag-icon • tag-icon microsoft-excel
Microsoft Excel、1 つのセルに複数の数式

1 つのセルに複数の数式を入力する方法についてサポートをお願いします。

g11に1を入力する場合、以下の式を使用します =if(H11="","",I11/(230*H11))

g11に3を入力する場合、以下の式を使用します =if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

前もって感謝します

答え1

同じ IF 関数を使用して G11 セルをテストすることもできます (この数式を 1 行で使用します)

=if(G11=1,  
    if(H11="","",I11/(230*H11)), 
    if(G11=3, 
            if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),
            ""
      )
   )

=if(G11=1,値が 1 かどうかをテストするには、
        if(H11="","",I11/(230*H11)),条件が True の場合、数式を 1 として実行します。False
        if(G11=3,の場合、値が 3 であるかどうかをテストします。G11
              if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),が 3 の場合は、2 番目の数式を実行します。G11
              ""の場合は他の何かを実行し、何もしません。close
      )if(G11=3,,)
)close if (G11=1,,)

答え2

いかがでしょうか

 =IF(G11=1,IF(H11="","",I11/(230*H11)),IF( G11=3,IF(H11="","",I11/(SQRT(3)*400*H11*(E11/100))),""))

答え3

きっとあなたは、2つの（オプションの）式がとても似ている：

=if(H11="","",I11/(230        *H11          ))
 ↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕           ↕↕↕↕          ↕↕
=if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

2 番目の式を並べ替えて単純化し、類似性を高めることができます。

 400*H11*(E11/100)
=400*(E11/100)*H11
=(400*E11/100)*H11
=(E11*400/100)*H11
=E11*(400/100)*H11
=E11 *   4   * H11
=4*E11*H11

2番目の式は次のようになります

=if(H11="","",I11/(sqrt(3)*4*E11*H11))

この類似性を利用して、全体の式（他のいくつかの回答で示されている）を次のように簡略化することができます。

=if(H11="","",I11/(IF(G11=1,230,IF(G11=3,sqrt(3)*4*E11,0))*H11))

が 1 または 3 以外の場合、明示的に 0 で除算されるため、エラーが発生することに注意してくださいG11。これが問題になる場合は、この回答を使用しないでください。

関連情報