タスクバーアイコンを上にスクロールして非アクティブなウィンドウを開く

Question 1

使用できますオートホットキーこれを実行するには、基本的に、カーソルがタスクバーまたはそこから開くプレビューサムネイルのいずれかにある場合にマウスホイールで上にスクロールすると左クリックが送信され、それ以外の場合は上にスクロールするように指示します。

これにはWindows APIを使用する必要があります。このスクリプトをテストしたところ、希望どおりに動作するようですが、クリックを送信すると思われます。どこでもウィンドウアイコンだけでなく、タスクバーにも表示します。残念ながら、これが私が管理できる最善のことです。

GetWinUnderMouse(what="Title")
{
    ; Allocate the memory (8 bytes) for the POINT structure
    VarSetCapacity(POINT, 8, 0)

    ; Call the GetCursorPos function with the address 
    ; of the POINT structure we just created
    DllCall("GetCursorPos", uint, &POINT)

    ; Use NumGet to get the information out of the structure
    ; the x-value is stored in the first 4 bytes, and 
    ; the y-value in the last 4
    X := NumGet(POINT, 0)
    Y := NumGet(POINT, 4)

    return GetWinAtCoords(X, Y, what)
}

GetWinAtCoords(x,y,what="Title")      ; by SKAN and Learning one
{
    ; Returns Title/ID/Class/PID of window at given coordinates
    WinID := DllCall( "GetAncestor", UInt      ; by SKAN
           ,DllCall( "WindowFromPoint", Int,X, Int,Y )
           , UInt, GA_ROOT := 2)
    if what = Title
    {
        WinGetTitle, WinTitle, ahk_id %WinID%
        Return WinTitle
    }
    else if what = ID
    Return WinID
    else if what = Class
    {
        WinGetClass, WinClass, ahk_id %WinID%
        Return WinClass
    }
    else if what = PID
    {
        WinGet, WinPID, PID, ahk_id %WinID%
        Return WinPID
    }
}

WheelUp::
    PointedClass := GetWinUnderMouse("Class")
    if (PointedClass = "TaskListThumbnailWnd" or PointedClass = "Shell_TrayWnd")
    {
        Send, {LButton}
    }
    else
    {
        Send, {WheelUp}
    }
Return

前にチルダ (~) を追加すると、左クリックが送信された場合でもホイールアップ機能が維持されます (その場合は、そこにある句WheelUp::を削除することもできます)。else

使用するには、プログラムをインストールし、スクリプトをファイルに入れて実行するだけです。

Answer