ユーザーが複数選択できるスライサー付きのピボット テーブルがあります。スライサーで選択した値をリストし、CONCATENATE を使用して別のセルに結合できるようにしたいと考えています。以下のコードを使用しています。
現時点では、セル L5:L7 にはスライサーで最初に選択した内容が入力されていますが、他の内容は入力されていません。
調査した結果、CUBESET 関数で解決できる可能性があることがわかりましたが、スプレッドシートで機能させることができません。そこで、VBA を試しました。何が問題なのか、誰か知っていますか?
Sub City_Click()
Dim cache As Excel.SlicerCache
Set cache = ActiveWorkbook.SlicerCaches("Slicer_City")
Dim sItem As Excel.SlicerItem
For Each sItem In cache.SlicerItems
If sItem.Selected = True Then Range("L5").Value = sItem.Name
If sItem.Selected = True Then Range("L6").Value = sItem.Name
If sItem.Selected = True Then Range("L7").Value = sItem.Name
Next sItem
End Sub
答え1
ここでは、ブックから直接呼び出すことができ、これを実行するユーザー定義関数を紹介します。この関数は、従来のピボットテーブル、OLAP/PowerPivot ピボットテーブル、テーブル スライサーなど、あらゆるタイプのスライサーで実行できます。これを標準コード モジュールに配置し、ブックに次のように入力します。
=SlicerItems("Slicer_City")
Public Function SlicerItems(SlicerName As String, Optional sDelimiter As String = "|") As String
Dim oSc As SlicerCache
Dim oSi As SlicerItem
Dim i As Long
Dim lVisible As Long
Dim sVisible() As String
On Error Resume Next
Application.Volatile
Set oSc = ThisWorkbook.SlicerCaches(SlicerName)
If Not oSc Is Nothing Then
With oSc
If .FilterCleared Then
SlicerItems = "(All)"
Else
If .OLAP Then
SlicerItems = Join(.VisibleSlicerItemsList, sDelimiter)
SlicerItems = Replace(SlicerItems, .SourceName, "")
SlicerItems = Replace(SlicerItems, ".&[", "")
SlicerItems = Replace(SlicerItems, "]", "")
Else
lVisible = .VisibleSlicerItems.Count
If .VisibleSlicerItems.Count = 1 Then
SlicerItems = .VisibleSlicerItems(1).Name
Else
ReDim sVisible(1 To lVisible)
For i = 1 To lVisible
sVisible(i) = .VisibleSlicerItems(i).Name
Next i
SlicerItems = Join(sVisible, sDelimiter)
End If
End If
End If
End With
Else
SlicerItems = SlicerName & " not found!"
End If
End Function
そして、それは次のようになります:
