☰

複数のフォルダの名前を変更するバッチファイルの作成についてサポートが必要です

tag-icon • tag-icon windows-7 batch
複数のフォルダの名前を変更するバッチファイルの作成についてサポートが必要です

12,000 個を超えるフォルダーがあり、各フォルダー内の最初のファイルの最初の 12 文字を使用して名前を変更したいと考えています。たとえば、「1」という名前のフォルダーがありますが、その中には複数の PDF ファイルがあり、リストの最初のファイルのファイル名は「201405090360.pdf」です。フォルダーの名前を「201405090360」に変更することは可能ですか?

答え1

以下は役に立つと認められました。エラー処理を増やすことで改善される可能性がありますが、目的を果たすか、より完全なスクリプトの開始点として使用できます。

ノート：

VBScript スクリプトは、以下のツリー ビューに従って親フォルダーと同じディレクトリに配置する必要があります。

先頭のstrPath変数は親ディレクトリの名前に変更する必要があります。つまり、「Start」から変更します。

実際に変更を加えるには、blnDoIt を false から true に変更します。

まず次のように実行することをお勧めします: cscript process.vbs > log.txt

ログ ファイルが正しい場合は、blnDoIt を true に変更します。

' Given this structure:
'
'│   process.vbs
'│
'└───Start
'    ├───1
'    │       123456789012aaa.txt
'    │       123456789013bbb.txt
'    │
'    ├───2
'    │       223456789012ccc.txt
'    │       223456789013ddd.txt
'    │
'    ├───3
'    │       323456789012eee.txt
'    │       323456789013fff.txt
'    │
'    ├───4
'    │       423456789012ggg.txt
'    │       423456789013hhh.txt
'    │
'    ├───5
'    │       523456789012iii.txt
'    │       523456789013jjj.txt
'    │
'    └───6
'            623456789013kkk.txt
'            623456789012jjj.txt

'===================================================================================    

dim strPath : strPath = "Start"
dim blnDoIt : blnDoIt = false

'===================================================================================
dim objFSO                  : set objFSO = CreateObject("Scripting.FileSystemObject")
dim objFolder               : set objFolder = objFSO.GetFolder(strPath)
dim strPGetAbsolutePathName : strPGetAbsolutePathName = objFSO.GetAbsolutePathName(strPath)
dim colSubfolders           : set colSubfolders = objFolder.Subfolders

'===================================================================================
for each objSubfolder in colSubfolders
    strNameOfFolder = objSubfolder.Name

    wscript.echo "Processing directory: " & strNameOfFolder
    strFileNameToUse = GetFileNameToUseAsParentDir (strNameOfFolder)

    if strFileNameToUse <> -1 then

      wscript.echo " > Chosen file to represent directory: " & strFileNameToUse
      strLeft12 = left (strFileNameToUse, 12)
      wscript.echo " > First 12 characters of file: " & strLeft12

      if blnDoIt then
        wscript.echo " > Renaming directory " & strPGetAbsolutePathName & "\" & strNameOfFolder & " to " & strPGetAbsolutePathName & "\" & strLeft12
        objFSO.MoveFolder strPGetAbsolutePathName & "\" & strNameOfFolder, strPGetAbsolutePathName & "\" & strLeft12
      else
        wscript.echo " > Rename directory " & strPGetAbsolutePathName & "\" & strNameOfFolder & " to " & strPGetAbsolutePathName & "\" & strLeft12
      end if

    else
    wscript.echo " > Skipping."
    end if

    wscript.echo ""
next
'===================================================================================

'===================================================================================
Function GetFileNameToUseAsParentDir(strDir)

    dim oFiles : Set oFiles = CreateObject("System.Collections.ArrayList")

    dim oF : set oF = objFSO.GetFolder(strPGetAbsolutePathName & "\" & strDir).Files

    wscript.echo " > " & oF.count & " files in directory."

    if oF.count > 0 then

      for each oFile In oF
        oFiles.Add oFile.name
      next

      oFiles.Sort

      GetFileNameToUseAsParentDir = oFiles(0)

    else
      GetFileNameToUseAsParentDir = -1
    end if

    set oFiles = nothing

End Function
'===================================================================================

答え2

Powershell を使用します。仕様を正しく理解していれば、これで問題は解決するはずです。

# Get List of subfolders
$Folders = Get-ChildItem <FOLDER> -Directory
# Process each subfolder
Foreach ($Subfolder in $Folders){
     # Get the names all files in current subfolder
     $FileNames = (Get-ChildItem $Subfolder.FullName -File).Name
     # If folder was not empty
     if ($FileNames) {
         # Replace current name of folder with first 12 chars of the name of the first file 
         Rename-Item $Subfolder.FullName $FileNames[0].Substring(0,12) -WhatIf
    }
}

実際のフォルダーに置き換えて、*.ps1 ファイルとして保存し、PowerShell を開いて実行します。

結果のみが表示され、下から 3 行目の「-Whatif」を削除するまで何も変更されません。

関連情報