☰

バッチファイルでファイルパスを更新するための日付式

tag-icon • tag-icon microsoft-excel batch batch-file
バッチファイルでファイルパスを更新するための日付式

私は、月次レポート用に、Excel ファイルのセットを .xls から .xlsx に変換するバッチ ファイルを作成しようとしています。

現在私が持っているものは次のとおりです:

"C:\Program Files (x86)\Microsoft Office\Office14\excelcnv.exe" -oice "H:\File Path\2018\Support\03 March\Other\03 Export.xls" "H:\File Path\2018\Support\03 March\Other\03 Export.xlsx"

ファイル パスの月を変更せずにこれを実行できるようにしたいと思います。これは次のようになります。

H:\File Path\2018\Support\03 March\Other

翌月にこれを実行すると、3 月 3 日の場所に「4 月 4 日」が自動的に入力されるようにしたいと思います。ファイル パスに 2018 も入力できれば便利です。これはバッチ ファイルで可能ですか?

ありがとう！

答え1

:: Q:\Test\2018\04\12\SU1313056.cmd
@Echo off&SetLocal EnableExtensions EnableDelayedExpansion

:: Get date in a locale/user-settings independent format
for /f "tokens=1-3 delims=.+-" %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
    ) do Set _DT=%%A
Set "yy=%_DT:~0,4%"&Set "MM=%_DT:~4,2%"&Set "dd=%_DT:~6,2%"

:: Build MonthName[01..12] array
Set i=100&Set "MonthName= January February March April May June July August September October November December"
Set "MonthName=%MonthName: ="&Set /a i+=1&Set "MonthName[!i:~-2!]=%"
:: Set MonthName

Set "Excel=C:\Program Files (x86)\Microsoft Office\Office14\excelcnv.exe"
Set "Src=H:\File Path\%yy%\Support\%MM% !MonthName[%MM%]!\Other\%MM% Export.xls"
Set "Dst=%Src%x"

:: Show command
Echo "%Excel%"  -oice^^
Echo   "%Src%" ^^
Echo   "%Dst%"

If Not exist "%Excel%" (Echo Can't find "%Excel%" & Pause & Exit /B 1)
If Not exist "%Src%"   (Echo Can't find "%Src%"   & Pause & Exit /B 1)

::DoIt
"%Excel%" -oice "%Src%" "%Dst%"

サンプル出力:

"C:\Program Files (x86)\Microsoft Office\Office14\excelcnv.exe" -oice^
"H:\File Path\2018\Support\04 April\Other\04 Export.xls" ^
"H:\File Path\2018\Support\04 April\Other\04 Export.xlsx"
"C:\Program Files (x86)\Microsoft Office\Office14\excelcnv.exe" が見つかりません
"H:\File Path\2018\Support\04 April\Other\04 Export.xls" が見つかりません

関連情報