☰

標準テンプレートのすべての目次 (ToC) スタイルの自動更新を無効にする (Word 2010 以降)

tag-icon • tag-icon microsoft-word microsoft-word-2010 styles templates
標準テンプレートのすべての目次 (ToC) スタイルの自動更新を無効にする (Word 2010 以降)

時々、現在の Word Normal ファイルを新しいコピーに置き換えて「最初からやり直し」、好みの設定でカスタマイズしたいことがあります。

標準ファイルでは、すべての目次 (ToC) スタイルが自動更新に設定されています。

私の知る限り、その設定を無効にする唯一の方法は 1 つずつ実行することであり、それには複数の手順 (スタイルをクリックし、[変更] をクリックし、[自動更新] を切り替え、[OK] をクリックし、これを繰り返します) が必要です。

すべての ToC スタイルを一度に変更する簡単な方法はありますか。たとえば、自動更新は次のようになります。

  • すべての ToC スタイルを同時に無効にしますか? または
  • 「クリーンな状態から始める」という目的を損なわない方法で保存および再利用されますか? (以前の dotm、dotx、または dot ファイルからのインポートはすべて目的に反すると思われますが、ライブラリまたは他の種類のファイルに何かが保存されている可能性があります。)

環境: それぞれ異なるバージョンの MSOffice がインストールされている複数の PC。

注: ToC スタイルの自動更新設定には長い歴史があります。「常にそのように行われていた」ようです。

答え1

自動更新の設定は、すべての TOC レベル スタイルのデフォルト設定です。組織内の誰かがこれを行わなかったため、Microsoft が Word の標準テンプレートでそのように設定しました。

これらすべてのスタイルの設定を同時に変更する方法は用意されていません。ただし、ドキュメント テンプレート ボタンの [開発] タブからアクセスできる [オーガナイザー] 機能を使用して、ドキュメント内で既に変更されているスタイルのグループを置き換えることができます。この手順は次のようになります。

  1. ドキュメントを作成し、その中で9つの目次スタイルを変更します。
  2. その文書を各マシンに持って行き、開きます
  3. Word のオーガナイザー機能を使用して、変更された 9 つの TOC スタイルをそのコンピューターの標準テンプレートにコピーします。

使用できるもう 1 つの方法は、各コンピューターで実行するマクロです。以下は使用できるマクロです。

Sub UpdateTemplateStyles()
Dim sty As word.Style
Dim odocStyles As word.Styles
Dim oTemplate As word.Document

On Error GoTo errHandler
Set oTemplate = ActiveDocument.attachedTemplate.OpenAsDocument
Set odocStyles = oTemplate.Styles
For Each sty In odocStyles
    Select Case sty.Type
        Case wdStyleTypeParagraph
            Select Case sty.NameLocal
                Case "TOC 1", "TOC 2", "TOC 3", "TOC 4", _
                    "TOC 5", "TOC 6", "TOC 7", "TOC 8", "TOC 9"
                    sty.AutomaticallyUpdate = False
            End Select
    End Select
Next sty
oTemplate.SaveAs2 FileName:=oTemplate.FullName, AddToRecentFiles:=False
DoEvents
oTemplate.Close
Exit Sub

errHandler:
MsgBox Err.Description, vbExclamation, "UpdateTemplateStyles"
End Sub

関連情報