☰

IP アドレスを設定するコマンドを設定した後、バッチ ファイルに IP 範囲を追加するにはどうすればよいでしょうか。

tag-icon • tag-icon command-line batch-file ip-address
IP アドレスを設定するコマンドを設定した後、バッチ ファイルに IP 範囲を追加するにはどうすればよいでしょうか。

以下のコマンドを使用して、set/p コマンドを使用して静的 IP アドレスを設定しようとしました。ただし、[詳細] タブに複数の IP 範囲を追加できるようにする add コマンドをどのように含めるのでしょうか?

つまり、私の静的IPは192.168.4.250 IP範囲ですが192.168.4.250 - 192.168.60.250

@echo off
echo ipv4 set address "Ethernet 3"
echo ipv4 netsh interface name="Ethernet 3"
set/p address=First Address:
set/p mask=First Mask:
set/p gate=First Gate:
netsh interface ipv4 set address name="Ethernet 3" static %address% %mask% %gate%

その結果

ここに画像の説明を入力してください

また、IP 変数は 3 番目のオクテットです192.168.%A.255が、1 番目と 2 番目のオクテットも変数に変更したいのですが、使用するコマンドが の場合、どうすればよいでしょうか%A IN (120,1,130)?

答え1

あなたの質問を100％理解できたかどうかはわかりません
が、私の英語が下手なのは100％確かです。申し訳ありません...

とにかく、私があなたを助けるものから遠く離れていないことを願っています...

@echo off && setlocal EnableDelayedExpansion

echo;iPv4 Set address "Ethernet 3" & echo;iPv4 netsh interface name="Ethernet 3"

:loop
cls & echo 

:: remove variable/value in using loop for command set "_var="
for %%i in ("address=", "mask=","gate=","dns1=","dns2=")do set "%%~i"

:: set variable/value in using loop for command to set /p "_var=Test to Screen" 
for %%i in ("address=First Address: ", "mask=First Mask: ","gate=First Gate: ","dns1=First DNS: ","dns2=Second DNS: "
     )do <con: set /p "_%%~i" || goto :loop

:: set variable/value in using loop for command set dns/ip 1st and 2nd
for %%i in (1.1.1.1,"1.0.0.1 index=2")do %__AppDir__%netsh.exe interface ipv4 add dns %%~i

:: set variable/value in using loop for command set "Ethernet 3" static ip/mask/gate
%__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %_address% %_mask% %_gate%

rem For /L (1ST.IPV4.OCT.IP)do ...
for /L %%A in (198,1,200
    )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.128.60.255 %_mask% %_gate%

rem For /L (1ST.2ND.IPV4.OCT)do... and Set %%A.2ND.IPV4.OCT
for /L %%A in (198,1,200)do for /l %%B in (128,1,130
     )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.%%~B.60.255 %_mask% %_gate%
        
rem For /L (1ST.2ND.3RD.OCT)do ... and Set %%A.%%B.%%C.OCT
for /L %%A in (198,1,200)do for /l %%B in (128,1,130)do for /l %%C in (4,1,60
    )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.%%~B.%%~C.255 %_mask% %_gate% 

rem For /L (1ST.2ND.3RD.4TH)do ... and Set %%A.%%B.%%C.%%D
for /L %%A in (198,1,200)do for /l %%B in (128,1,130)do for /l %%C in (4,1,60)do for /l %%D in (253,1,254
     )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.%%~B.%%~C.%%~D %_mask% %_gate%

endlocal & goto :eof || exit /b 0
  • 観察:新しく割り当てられた IP との接続をテストし、成功した場合はループを終了するには、追加のコマンドが役立つと思います。
@echo off && setlocal EnableDelayedExpansion

echo;iPv4 Set address "Ethernet 3" & echo;iPv4 Netsh Interface Name="Ethernet 3"

:loop
cls & echo; & for %%i in ("address=", "mask=","gate=","dns1=","dns2=")do set "%%~i"

for %%i in ("address=First Address: ", "mask=First Mask: ","gate=First Gate: ","dns1=First DNS: ","dns2=Second DNS: "
     )do <con: set /p "_%%~i" || goto :loop

for %%i in (1.1.1.1,"1.0.0.1 index=2")do %__AppDir__%netsh.exe interface ipv4 add dns %%~i
%__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %_address% %_mask% %_gate%

for /L %%A in (198,1,200
    )do ;"%__AppDir__%netsh.exe" interface ipv4 set address name="Ethernet 3" static %%~A.128.60.255 %_mask% %_gate% && (
         <con: %__AppDir__%ping.exe 1.1.1.1 -f -4 -w 4|2>nul %__AppDir__%findstr.exe .*Received.=.[1-4].>nul && goto %:^)
        ) 

for /L %%A in (198,1,200)do for /l %%B in (128,1,130
     )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.%%~B.60.255 %_mask% %_gate% && (
         <con: %__AppDir__%ping.exe 1.1.1.1 -f -4 -w 4|2>nul %__AppDir__%findstr.exe "Received.=.[1-4]">nul && goto %:^)
        )
        
for /L %%A in (198,1,200)do for /l %%B in (128,1,130)do for /l %%C in (4,1,60
    )do %__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%~A.%%~B.%%~C.255 %_mask% %_gate% && (
         <con: %__AppDir__%ping.exe 1.1.1.1 -f -4 -w 4|2>nul %__AppDir__%findstr.exe "Received.=.[1-4]" >nul && goto %:^)
        )
        
for /L %%A in (198,1,200)do for /l %%B in (128,1,130)do for /l %%C in (4,1,60)do for /l %%D in (253,1,254
     )do ;%__AppDir__%netsh.exe interface ipv4 set address name="Ethernet 3" static %%A.%%B.%%C.%%D %_mask% %_gate% && (
         <con: %__AppDir__%ping.exe 1.1.1.1 -f -4 -w 4|2>nul %__AppDir__%findstr.exe "Received.=.[1-4]">nul && goto %:^)
        )
%:^) 
:: Your next command came here...
endlocal & goto :eof || exit /b 0

関連情報