☰

列データをアルファベット順に並べ替える

tag-icon • tag-icon linux awk
列データをアルファベット順に並べ替える

列データの順序をアルファベット順で変更したい

入力

c,a,b
e,k,d

出力

a,b,c
d,e,k

現在、私は以下のコードを使用しています

awk -F"," -v OFS="," '{ 
if($1<=$2 && $2<=$3) 
{print $1,$2,$3} 
else if($1<=$2 && $3<=$2) 
{print $1,$3,$2} 
else if($2<=$1 && $1<=$3) 
{print $2,$1,$3} 
else if($2<=$1 && $3<=$1) 
{print $2,$3,$1} 
else if($3<=$2 && $2<=$1) 
{print $3,$2,$1} 
else 
{print $3,$1,$2}}' test.txt

4列以上のファイルを処理するためのより簡単なソリューションを教えてください。

答え1

よろしければperl：

$ perl -F, -lane 'print join ",", sort @F' ip.txt
a,b,c
d,e,k

-F,区切り文字として分割する入力行を指定し、結果は配列,で取得できます。@F

sort @Fアルファベット順にソートされ、結果の配列は区切り文字をjoin使用して結合されます。,


とGNU awk

$ awk 'BEGIN{PROCINFO["sorted_in"] = "@val_str_asc"}
       {s = ""; c=0; split($0,a,",");
        for(k in a) s = c++ ? s "," a[k] : a[k];
        print s}' ip.txt
a,b,c
d,e,k

見るgawk マニュアル: 定義済み配列スキャン順序の使用上記で使用した配列の順序の詳細については

答え2

sorted_in に GNU awk を使用する場合:

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    arr,idx,sep,outStr) {
    PROCINFO["sorted_in"] = "@val_str_asc"
    split(inStr,arr)
    for (idx in arr) {
        outStr = outStr sep arr[idx]
        sep = OFS
    }
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

sortまたは任意の awk でも実行できますが、入力行ごとにUNIX を呼び出すシェルを生成するため、実行速度がはるかに遅くなります。

$ cat tst.awk
BEGIN {
    FS=OFS=","
}
{
    sub(/\r$/,"")
    print sort($0)
}

function sort(inStr,    cmd,line,sep,outStr) {
    gsub(/,/,"\n",inStr)
    cmd = "printf \047%s\n\047 \047" inStr "\047 | sort"
    while ( (cmd | getline line) > 0 ) {
        outStr = outStr sep line
        sep = OFS
    }
    close(cmd)
    return outStr
}

$ awk -f tst.awk file
a,b,c
d,e,k

これはsub(/\r$/,"")、投稿されたサンプル入力には DOS の行末があるが、投稿された期待出力には DOS の行末がないためです。

答え3

perl -nlE 'say join ",", sort split ","'   file.txt

説明：

            for each line like "r,d,a":
 "r,d,a"
    ↓          split ","  it
("r","d","a")
    ↓          sort       it
("a","d","r")
    ↓          join ","   it
 "a,d,r"
               say it

関連情報