gnuplot (epslatex) では線のスタイルが適用されません

Question

こんにちは。gnuplot (epslatex ターミナル) を使用して、同じプロットに 2 つの曲線を描画したいと思います。gnuplot スクリプトを使用していますが、コマンドを使用して定義された線の色が適用されないことを除けば、問題なく動作しますset style line。

スクリプトは次のとおりです。

set terminal epslatex color colortext size 9cm,5cm
set size 1,1
set output "lorenzov_faktor.tex"

set xrange [0:10]
set yrange [0:10]

set xtics ("$0c$" 0, "$c$" 10)
set ytics ("$0$" 0, "$1$" 1, "$\\infty$" 10)

set style line 1 lc rgb "#FF0055"
set style line 2 lc rgb "#2C397D"

unset grid

set ylabel "$\\gamma$"
set xlabel "$u$"

set key left top

f(x) = 1/sqrt(1 - (x/10)**2) 
g(x) = 1

set xrange [0:11]
set yrange [0:9]

plot f(x) ls 2 lw 3 lt 1 title "$\\gamma$", g(x) ls 1 lw 1 lt 2 notitle

色が線スタイルの定義と一致しないプロットが生成されます。

Answer 1

lt 1および は、ユーザー定義の線スタイルの代わりにデフォルトの線種を復元するため、スクリプトから削除する必要があります。 または、を実行するときにlt 2を使用して、色に影響を与えずに線種 (実線、破線など) を変更することもできます。ltset style line

set style line 1 lc rgb "#FF0055" lt 1
set style line 2 lc rgb "#2C397D" lt 3

...

plot f(x) ls 2 lw 3 title "$\\gamma$", g(x) ls 1 lw 1 notitle