☰

awk と while read 行を使用して行を比較する

tag-icon • tag-icon text-processing sed awk search
awk と while read 行を使用して行を比較する

17k 行のファイルと 4k 行のファイルの 2 つがあります。2 番目のファイルの各行で位置 115 から位置 125 を比較し、一致した場合は、最初のファイルの行全体を新しいファイルに書き込みたいと考えていました。「cat $filename | while read LINE」を使用してファイルを読み取るという解決策を思いつきましたが、完了するまでに約 8 分かかります。この処理時間を短縮するために、「awk」を使用するなどの方法はありますか。

私のコード

cat $filename | while read LINE
do
  #read 115 to 125 and then remove trailing spaces and leading zeroes
  vid=`echo "$LINE" | cut -c 115-125 | sed 's,^ *,,; s, *$,,' | sed 's/^[0]*//'`
  exist=0
  #match vid with entire line in id.txt
  exist=`grep -x "$vid" $file_dir/id.txt | wc -l`
  if [[ $exist -gt 0 ]]; then
    echo "$LINE" >> $dest_dir/id.txt
  fi
done

答え1

空白を削除するように更新された次のコードが機能するはずです。

#!/usr/bin/awk -f
# NR is the current line number (doesn't reset between files)
# FNR is the line number within the current file
# So NR == FNR  takes only the first file
NR == FNR {
    # Mark the current line as existing, via an associative array.
    found[$0]=1

    # Skip to the next line, so we don't go through the next block
    next
}
{
    # Take the columns we're looking for
    cols = substr($0,115,11)

    # Strip whitespace (space and tab) from the beginning (^) and end ($) 
    gsub(/^[ \t]+/,"", cols)
    gsub(/[ \t]+$/,"", cols)

    # Check the associative array to see if this was in the first file
    # If so, print the full line
    if(found[cols]) print;
}

それをファイルに入れて、次のいずれかで呼び出します

awk -f script.awk patterns.txt full.txt
./script.awk patterns.txt full.txt

関連情報