☰

下記のAwkスクリプトについて説明してください

tag-icon • tag-icon shell-script awk
下記のAwkスクリプトについて説明してください

どなたか、以下に書かれた AWK スクリプトを段階的に説明していただけますか。

フラット ファイル データをフォーマットするために、スクリプトに以下のコードを記述しました。再利用できるように理解したいだけです。私は Unix の専門家ではありませんが、タスクが割り当てられています。どうか助けてください。

awk -vsep=$SEPARATOR 'NR>2{if(NF){if(!s){gsub(" *"sep"[ \t]*",sep);printf "%d%s\n",NR-2,$0}}else s=1}' file_name > new_file

 # where $SEPARATOR = ';'

前もって感謝します。

答え1

コマンドライン オプションは、-vsep=$SEPERATORawk 変数sep(検索/置換で使用される) を指定した値に;設定します。

# NR = Number of current Record, or line number
# Skip the first line
if ( NR > 2 ) {

  # NF = Number of fields in the current record
  # If the line contains something other than a blank line or the 
  # awk field separator characters (whitespace by default)
  if ( NF ) {

    # If we have not seen a blank line (script flag s)
    if ( !s ) {

      # Search the current line repeatedly (gsub) for any number of spaces (" *") 
      # before a ";" then any number of spaces or tabs ([ \t]*) after the `;`
      # and replace it all with just a ";"
      gsub( " *"sep"[ \t]*", sep );

      # Print the line number, 0 based (NR-2) as a signed decimal integer (`%d`)
      # then the complete line ($0) followed by a new line character (\n)
      printf "%d%s\n", NR-2, $0;
    }

  } else { 

    # Set the "seen a blank line" flag
    s = 1
  }

}

file_name > new_file出力を新しいファイルに書き込みますnew_file

ちなみに、スクリプトを次のように構成すると、空白行の後に大量のデータがある場合でも、読みやすくなり、処理が速くなります。

awk -vsep=$SEPERATOR '{

# Skip the first line
if (NR == 1) { next; }

# Stop processing if we see a blank line
if (NF == 0) { exit; }

# Remove spaces before and spaces/tabs after separator
gsub( " *"sep"[ \t]*", sep );

# Print the line with a record number starting from 0
printf "%d%s\n", NR-2, $0;

}' file_name > new_file

関連情報