次のような入力があります:
Fred apples 20
Susy oranges 5
Mark watermellons 12
Robert pears 4
Robert oranges 17
Terry oranges 9
Lisa peaches 7
Susy oranges 12
Mark grapes 39
Anne mangoes 7
Greg pineapples 3
Oliver rockmellons 2
Betty limes 14
そして次のような出力が欲しいです:
Anne:
mangoes 7
Oliver:
rockmellons 2
Greg:
pineapples 3
Mark:
watermellons 12
grapes 39
Terry:
oranges 9
Susy:
oranges 17
Lisa:
peaches 7
Fred:
apples 20
Robert:
oranges 17
pears 4
Betty:
limes 14
私はawkコマンドを使ってこれを実行しようとしています。私のコードは次のようになります:
{
lines[$1] = (lines[$1] ? lines[$1] "\n " $2 " " $3 : $1 ":\n " $2 " " $3)
}
END {
for (line in lines) print lines[line]
}
2 番目の列の重複を比較し、数値を合計します。
答え1
配列の配列を持つ GNU awk を使用する (gawk バージョン 4 が必要になる場合があります)
gawk '
NF { n[$1][$2] += $3 }
END {
for (name in n) {
print name ":"
for (fruit in n[name])
printf "%16s %2d\n", fruit, n[name][fruit]
}
}
'
答え2
出力がソートされていても構わない場合は、現在の人物と現在の果物を追跡し、どちらかが変化するまで合計することができます。
#!/usr/bin/awk -f
NF {
if (who != $1) {
if (count > 0) {
printf "%16s %2d\n", fruit, count
}
who = $1
printf "%s:\n", who
fruit = ""
count = 0
}
if (fruit != $2) {
if (count > 0) {
printf "%16s %2d\n", fruit, count
}
fruit = $2
count = $3
} else {
count += $3
}
}
END {
printf "%16s %2d\n", fruit, count
}
これを次のようにフィードしますsort -k1,1 -k2,2
:
sort -k1,1 -k2,2 file.txt | ./script.awk