☰

Gibt es ein Programm zur Analyse der NTP-Serverstatistiken?

tag-icon • tag-icon 12.04 ntp
Gibt es ein Programm zur Analyse der NTP-Serverstatistiken?

Ich verwende Ubuntu 12.04 und der NTP-Server läuft anscheinend einwandfrei. Ich lasse den Meinberg NTP-Server auf meinen beiden Windows 7-Rechnern laufen und verwende den zugehörigen Servermonitor, um den Überblick zu behalten, was er tut.

Gibt es einen ähnlichen Linux-Monitor, vorzugsweise einen mit einer GUI, die mir zeigen kann, wie sich meine Uhr verhält usw.?

Antwort1

Keine genaue Antwort auf Ihre Frage, aber ich sehe, Sie erwähnen, dass Sie jetzt ein Gnuplot-Skript verwenden, das /var/log/ntp/loopstats analysiert. Ich mache das Gleiche, und unten ist das Skript, das ich selbst verwende.

Wenn jemand etwas Besseres macht, wäre ich auch neugierig.

#! /usr/bin/gnuplot
# Remember to check you have these lines in /etc/ntp.conf and that ntpd is actually running:
#    statsdir /var/log/ntpstats/
#    statistics loopstats peerstats clockstats
#    filegen loopstats file loopstats type day enable
#    filegen peerstats file peerstats type day enable
#    filegen clockstats file clockstats type day enable

# Resolution: fullscreen
set term x11 size `xrandr | awk '/\*/{sub(/x/,",");print $1; exit}'`
set grid
set bars 0.4
set y2tics
set y2range [0:]
set ytics nomirror
set xdata time
set timefmt "%s"
set format x "%T"
set title "NTP statistics"
set ylabel "Clock offset / Roundtrip delay (ms)"
set y2label "Frequency offset (seconds per day)"
set xlabel "Time of day"
local_time = `date +%s --utc -d "12:00:00 $(date +%z)"`
utc_time   = `date +%s --utc -d "12:00:00"`
localdifferencefromUTC = utc_time - local_time
timeoffsettoday = `date +%s --utc -d "today 0:00"` + localdifferencefromUTC
plot \
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($3*1000):($5*1000/2) t "Clock offset" w errorlines lt 1 lw 2 pt 187, \
  "/var/log/ntpstats/peerstats" u ($2+timeoffsettoday):($6*1000):($8*1000/2) t "Roundtrip delay" w errorbars lt 26 pt 26,\
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($4*0.0864):($6*0.0864/2) axes x1y2 t "Frequency offset" w errorline lt 7 pt 65,\
  0 w l lt -1
pause mouse close

Antwort2

ntp.org bietet vieleLinkszu Überwachungstools auf seiner Website

verwandte Informationen