☰

Ergebnis:

tag-icon • tag-icon awk
Ergebnis:

Ich muss die Differenz zwischen dem Maximal- und Minimalwert eines Datensatzes (3 $) für jede eindeutige ID (1 $) ausdrucken.

Datendatei

Id str mt no  
101 2 550 1
101 3 540 2
101 3 350 3
101 4 600 4
101 4 700 5
102 1 400 1
102 4 500 2
102 4 350 3
102 3 550 4
103 3 500 1
103 4 300 2
103 3 550 3

Ausgabe

    Id str mt no diff 
    101 2 550 1 350
    101 3 540 2 350
    101 3 350 3 350
    101 4 600 4 350
    101 4 700 5 350
    102 1 400 1 200
    102 4 500 2 200
    102 4 350 3 200 
    102 3 550 4 200
    103 3 500 1 250
    103 4 300 2 250
    103 3 550 3 250

Antwort1

awkAnsatz mit mehrdimensionalen Arrays undsortierenFunktion:

awk 'NR==1{ h=$0; } NR>1 { b[NR]=$0;a[$1][length(a[$1])+1]=$3; }
    END { print h,"diff";
        for (i in a) { asort(a[i]) } 
        for (k=2;k<=NR;k++) { 
            split(b[k],sep); max=length(a[sep[1]]); 
            print b[k],a[sep[1]][max] - a[sep[1]][1]
        } 
    }' file

Die Ausgabe:

Id str mt no   diff
101 2 550 1 350
101 3 540 2 350
101 3 350 3 350
101 4 600 4 350
101 4 700 5 350
102 1 400 1 200
102 4 500 2 200
102 4 350 3 200
102 3 550 4 200
103 3 500 1 250
103 4 300 2 250
103 3 550 3 250

Antwort2

Hier ist eine "pädagogische" Version:

awk '
NR == 1 {
  header=$0
}
NR > 1 {
  line[NR]=$0
  if($4==1) {
    min[$1]=max[$1]=$3
  }
  else {
    if(min[$1]>$3) min[$1]=$3
    if(max[$1]<$3) max[$1]=$3
  }
}
END {
  printf("%s diff\n",header)
  for(i=2;i<=NR;i++) {
    split(line[i],e)
    printf("%s %d\n",line[i],max[e[1]]-min[e[1]])
  }
}
' datafile > output

Vorausgesetzt, die Sortierung der ID-Spalte ist garantiert, gibt es hier eine schnellere Version, die zudem deutlich weniger Speicher verbraucht:

awk 'function f() {for(i in r) printf("%s %d\n",r[i],u-l); delete r}
NR == 1 {printf("%s diff\n",$0)}
NR > 1 {if($4==1) {f(); l=u=$3}
  else {if(l>$3)l=$3; if(u<$3)u=$3}
  r[$4]=$0 }
END {f()}
'  datafile > output

Beide dieser Skripte generieren die angeforderte Ausgabe und funktionieren mit POSIX-kompatiblen awk-Implementierungen, d. h. sie erfordern keine GNU awk-Erweiterungen wie asort.

Antwort3

perl -lane '
     push @A, $_; next if $. == 1; ($a, $b) = @F[0,2];

     $b > ($M{$a} // -Inf)  and $M{$a} = $b;
     $b < ($m{$a} // +Inf)  and $m{$a} = $b;

     END{$,=$";
        print shift @A, q/diff/;
        ($a) = /\d+/g, print $_, $M{$a} - $m{$a} for @A;
     }
' datafile

Ergebnis:

Id str mt no diff
101 2 550 1 350
101 3 540 2 350
101 3 350 3 350
101 4 600 4 350
101 4 700 5 350
102 1 400 1 200
102 4 500 2 200
102 4 350 3 200
102 3 550 4 200
103 3 500 1 250
103 4 300 2 250
103 3 550 3 250

Antwort4

Hier ist eine Zwei-Pass-Lösung

awk -f runawk first_pass=1 file first_pass=0 file

runawkwobei die Inhalte von

FNR == 1 && /^Id/{
  if (!first_pass) print
  next
}
first_pass{
  if (!($1 in max)){
    min[$1] = max[$1] = $3
    next
  }
  max[$1] = $3 > max[$1]? $3: max[$1]
  min[$1] = $3 < min[$1]? $3: min[$1]
}
!(first_pass){
    print $1, $2, $3, max[$1] - min[$1]
}

verwandte Informationen