☰

Vlookup mit doppelten Werten durch AWK

tag-icon • tag-icon awk
Vlookup mit doppelten Werten durch AWK

Sie müssen eine visuelle Suche aus zwei verschiedenen Dateien mit doppelten Einträgen durchführen:

Datei 1

abc     10
xyz     20
bhy     30
hgf     40

Datei 2

a   abc     
b   xyz     
c   bhy     
d   abc     
e   abc     
f   xyz

Erforderliche Ausgabe:

abc     10  a,d,e
xyz     20  b,f
bhy     30  c
hgf     40  Not_Available

Antwort1

AwkLösung:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END { for (i in a) print i, a[i] }' OFS='\t' file1 file2

Die Ausgabe:

bhy 30  c
abc 10  a,d,e
xyz 20  b,f

Verwenden Sie für Ihre letzte Bedingung die folgende Änderung:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END {
         for (i in a) print i, a[i] (a[i] ~ /\t$/? "Not_Available" : "")
     }' OFS='\t' file1 file2

Antwort2

Mit awk

awk -v OFS='\t' '
    NR == FNR {val[$1]=$2; next} 
    {items[$2] = items[$2] " " $1}
    END {
        for (a in val) {
            sub(/^ /, "", items[a])
            gsub(/ /, ",", items[a]) 
            print a, val[a], items[a]
        }
    }
' file1 file2

bhy     30      c
abc     10      a,d,e
xyz     20      b,f

Wenn Sie es sortiert haben möchten, leiten Sie weiter in| sort -k2,2n

Nur zum Spaß, ein kniffliges Stück Perl

perl -lae '
    if ($. == ++$nr) { $val{$F[0]} = $F[1] }
    else             { push @{$items{$F[1]}}, $F[0] }
  } continue {
    close ARGV if eof
  } END { 
    printf "%s\t%s\t%s\n", $_, $val{$_}, join(",", @{$items{$_}}) for keys %items 
' file1 file2

verwandte Informationen