☰

Erhalten Sie den Prozentsatz unterschiedlicher Werte mit Abhängigkeit von der 2. Spalte

tag-icon • tag-icon microsoft-excel worksheet-function
Erhalten Sie den Prozentsatz unterschiedlicher Werte mit Abhängigkeit von der 2. Spalte

Ich habe eine Umfrage an Leute verschickt. Eine Frage war nach ihrem Geschlecht und eine andere, ob sie Kopfschmerzen haben. Ich habe jetzt die Ergebnisse in einer Excel-Datei und versuche, sie zu analysieren.
Aber ich habe Probleme, eine Statistik zu berechnen.

Bildbeschreibung hier eingeben

Ich möchte berechnen, wie viel Prozent der Menschen, die unter Kopfschmerzen leiden, Männer und wie viel Prozent Frauen sind.

Ich weiß, das Konzept ist
# people that are men AND experience headaches /
# of people that experience headaches

Wie erhalte ich diese Prozentsätze?

Antwort1

Ein Normalbetrieb countifmit mehr als einer Spalte als Abhängigkeit funktioniert nicht. Verwenden Sie SUMPRODUCTstattdessen.

  1. Diese Formel zählt alle Zeilen, in denenMännerUNDKopfschmerzenist wahr.

    =SUMPRODUCT((A1:A100=1)*(B1:B100=1))

    Beachten Sie, dass Sie die Formel bei Bedarf um eine dritte oder weitere Abhängigkeiten erweitern können »
    ...*(C1:C100=x)...

    Beispielausgabe = 2

  2. Um die Anzahl der Personen mit Kopfschmerzen zu ermitteln, verwenden Sie COUNTIF, da wir hier nur nach einer Spalte suchen müssen

    COUNTIF(B:B,1)

    Beispielausgabe = 6

  3. Jetzt müssen Sie nur noch diese beiden Formeln kombinieren

    =SUMPRODUCT((A1:A100=1)*(B1:B100=1)) / COUNTIF(B:B,1)
=SUMPRODUCT((A1:A100=2)*(B1:B100=1)) / COUNTIF(B:B,1)

    Beispielausgabe = 2/6 = 0,333333 = 33,33 %
    Beispielausgabe = 4/6 = 0,666667 = 66,67 %

    Die erste Formel ist für Männer mit Kopfschmerzen, die zweite für Frauen mit Kopfschmerzen

Es gibt einige Alternativen zur ersten Formel =SUMPRODUCT((A1:A100=1)*(B1:B100=1)), die alle zum gleichen Ergebnis führen. Wählen Sie Ihren Favoriten:

  • {=SUM(IF((A1:A100=1)*(B1:B100=1),1))}

  • {=SUM((A1:A100=1)*(B1:B100=1))}

  • {=SUM(N(A1:A100&B1:B100=1&1))}

  • =COUNTIFS(A:A;1,B:B,1)» nicht verfügbar in Excel 2003

  • {=SUM((A:A=1)*(B:B=1))} » nicht verfügbar in Excel 2003

Beachten Sie, dass die meisten von ihnenArray-Formeln {...}CTRLdie mit + SHIFT+ eingegeben werdenENTER

Quelle

Antwort2

AVERAGEEine andere Möglichkeit besteht darin, eine Funktion wie diese zu verwenden

=AVERAGE(IF(B2:B100=1,IF(A2:A100=1,1,0)))

bestätigt mit CTRL+ SHIFT+ENTER

Wenn B2:B100 = 1 (Kopfschmerzen), wird 1 oder 0 zurückgegeben, je nachdem, ob es sich um Männer oder Frauen handelt. Der Durchschnitt dieser Werte ergibt den richtigen Prozentsatz.

verwandte Informationen