☰

evil-mode '>' evil-shift-left verliert Auswahl

tag-icon • tag-icon emacs evil
evil-mode '>' evil-shift-left verliert Auswahl

Gibt es einen Grund, warum der Evil-Mode-Evil-Shift-Left die Auswahl verliert?

Ich hätte beispielsweise gerne die Möglichkeit, in der Auswahl mehrmals „>“ und „<“ zu drücken, um den Text nach links und rechts zu verschieben.

Hier ist die Implementierung unten. Gibt es einen Ratschlag, um dieses Verhalten zu ändern?

böse-befehle.el

(evil-define-operator evil-shift-right (beg end &optional count)
  "Shift text from BEG to END to the right.
The text is shifted to the nearest multiple of `evil-shift-width'
\(the rounding can be disabled by setting `evil-shift-round').
See also `evil-shift-left'."
  :type line
  (interactive "<r><vc>")
  (let ((beg (set-marker (make-marker) beg))
        (end (set-marker (make-marker) end)))
    (dotimes (i (or count 1))
      (if (not evil-shift-round)
          (indent-rigidly beg end evil-shift-width)
        (let* ((indent
                (save-excursion
                  (goto-char beg)
                  (evil-move-beginning-of-line nil)
                  (while (and (< (point) end) (looking-at "[ \t]*$"))
                    (forward-line))
                  (if (> (point) end) 0
                    (current-indentation))))
               (offset (- evil-shift-width (mod indent evil-shift-width))))
          (indent-rigidly beg end offset))))
    (set-marker beg nil)
    (set-marker end nil)))

Antwort1

Dies überlastet das aktuelle Verhalten zur erneuten Auswahl (zu finden unterdjoyner/dotfiles/emacs/lisp/evil-config.el#L36-L40).

; Overload shifts so that they don't lose the selection
(define-key evil-visual-state-map (kbd ">") 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map (kbd "<") 'djoyner/evil-shift-left-visual)
(define-key evil-visual-state-map [tab] 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map [S-tab] 'djoyner/evil-shift-left-visual)

(defun djoyner/evil-shift-left-visual ()
  (interactive)
  (evil-shift-left (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))

(defun djoyner/evil-shift-right-visual ()
  (interactive)
  (evil-shift-right (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))

Antwort2

Sehr ähnlich der bereits von @avsej gegebenen Antwort, aber die Verwendung call-interactivelystellt sicher, dass evil-shift-{left,right} alle seine Argumente erhält (z. B. COUNT). Zum Beispiel:

(defun my-visual-shift-left ()
  (interactive)
  (call-interactively 'evil-shift-left)
  (evil-normal-state)
  (evil-visual-restore))

Auf diese Weise können Sie immer noch jeweils um mehr als eine Einheit einrücken (z. B. 4>).

verwandte Informationen