☰

Eindeutige Werte in 3 Spalten finden

tag-icon • tag-icon microsoft-excel-2010
Eindeutige Werte in 3 Spalten finden

Ich habe 3 Spalten in Excel. Ich möchte eindeutige Werte in den Spalten A, B und C finden.

Also:

  1. Indem ich in Spalte A nachschaue, möchte ich die eindeutigen Werte finden, die nicht in B oder C stehen.
  2. Indem ich in Spalte B nachschaue, möchte ich eindeutige Werte finden, die nicht in Spalte A oder C stehen.
  3. Indem ich in Spalte C nachschaue, möchte ich eindeutige Werte finden, die nicht in Spalte A oder B stehen.

Das habe ich in Spalte A eingetragen

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

Das habe ich in Spalte B eingetragen

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Das habe ich in Spalte C eingetragen

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Dadurch erhalte ich doppelte Werte in den drei Spalten, die eindeutig sein müssen. Vielleicht mache ich das Ganze einfach nur sehr kompliziert. Irgendeine Idee, wie das geht?

Das Tabellenbeispiel:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

In diesem Fall möchte ich die eindeutige Nummer in jeder Spalte. Für Spalte A lauten also die eindeutigen Werte, die nicht in den Spalten B oder C stehen, = 1,4,5,6. In Spalte B lauten die eindeutigen Werte, die nicht in A oder C stehen, = 8,9, 10. In Spalte C lauten die eindeutigen Werte, die nicht in B oder C stehen, = 11, 12, 13. Für diese drei Formeln möchte ich eine Formel in den Spalten D, E, F erstellen.

ABC 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

In diesem Fall möchte ich die eindeutige Nummer in jeder Spalte. Für Spalte A lauten also die eindeutigen Werte, die nicht in den Spalten B oder C stehen, = 1,4,5,6. In Spalte B lauten die eindeutigen Werte, die nicht in A oder C stehen, = 8,9, 10. In Spalte C lauten die eindeutigen Werte, die nicht in B oder C stehen, = 11, 12, 13. Für diese drei Formeln möchte ich eine Formel in den Spalten D, E, F erstellen.

Antwort1

Sie können in D1 eine Array-Formel † wie die folgende verwenden :

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

Die Formeln in den anderen Spalten sind ähnlich:

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

Und aus Ihrer Beispieltabelle erhalte ich Folgendes:

Bildbeschreibung hier eingeben

Wenn Ihre Formel in einer anderen Zeile als der ersten beginnt, muss die Formel etwas geändert werden, da die verwendete Formel ROW()von der Zeile abhängt, in der die Formel eingefügt wird.

† Hinweis: Um die Formel zu verwenden, müssen Sie Ctrl+ gedrückt halten und dann nach dem Einfügen Shiftdrücken .Enter

verwandte Informationen