Derzeit erhalten wir von unseren Kunden mit Excel ausgefüllte E-Formulare, daher habe ich einen Ordner voller Arbeitsmappen.
Jede Arbeitsmappe besteht aus mehreren Blättern.
Ich muss alle Arbeitsmappen durchsuchen, um zu sehen, ob die Bereiche „J8:Y8 auf Blatt 3“ und „G8:AC8 auf Blatt 4“ ausgefüllt wurden, da diese einer genaueren Prüfung bedürfen. Allerdings sind diese Blätter nur in wenigen Fällen ausgefüllt.
Außerdem hat jedes Arbeitsbuch einen völlig anderen Namen.
Ich habe diesen Code (unten) online gefunden, der im Prinzip das tut, was ich brauche. Allerdings durchsucht er jedes Blatt der Arbeitsmappe nach einem bestimmten „Wert“.
Sub SearchFolders()
Dim fso As Object
Dim fld As Object
Dim strSearch As String
Dim strPath As String
Dim strFile As String
Dim wOut As Worksheet
Dim wbk As Workbook
Dim wks As Worksheet
Dim lRow As Long
Dim rFound As Range
Dim strFirstAddress As String
On Error GoTo ErrHandler
Application.ScreenUpdating = False
'Change as desired
strPath = "c:\MyFolder"
strSearch = "Specific text"
Set wOut = Worksheets.Add
lRow = 1
With wOut
.Cells(lRow, 1) = "Workbook"
.Cells(lRow, 2) = "Worksheet"
.Cells(lRow, 3) = "Cell"
.Cells(lRow, 4) = "Text in Cell"
Set fso = CreateObject("Scripting.FileSystemObject")
Set fld = fso.GetFolder(strPath)
strFile = Dir(strPath & "\*.xls*")
Do While strFile <> ""
Set wbk = Workbooks.Open _
(Filename:=strPath & "\" & strFile, _
UpdateLinks:=0, _
ReadOnly:=True, _
AddToMRU:=False)
For Each wks In wbk.Worksheets
Set rFound = wks.UsedRange.Find(strSearch)
If Not rFound Is Nothing Then
strFirstAddress = rFound.Address
End If
Do
If rFound Is Nothing Then
lRow = lRow + 1
.Cells(lRow, 1) = wbk.Name
.Cells(lRow, 2) = wks.Name
.Cells(lRow, 3) = rFound.Address
.Cells(lRow, 4) = rFound.Value
Else
Exit Do
End If
Set rFound = wks.Cells.FindNext(After:=rFound)
Loop While strFirstAddress <> rFound.Address
Next
wbk.Close (False)
strFile = Dir
Loop
.Columns("A:D").EntireColumn.AutoFit
End With
MsgBox "Done"
ExitHandler:
Set wOut = Nothing
Set wks = Nothing
Set wbk = Nothing
Set fld = Nothing
Set fso = Nothing
Application.ScreenUpdating = True
Exit Sub
ErrHandler:
MsgBox Err.Description, vbExclamation
Resume ExitHandler
End Sub
Antwort1
Dieser Code funktioniert folgendermaßen:
- Öffnen Sie an einem beliebigen Ort eine neue Arbeitsmappe.
- Fügen Sie den VBA-Code in das Makro ein
Geben Sie in Blatt 1, Zelle A1, den Pfad zum Ordner mit den Arbeitsmappen ein, zum Beispiel:
C:\users\yourname\folder\
In Zelle A2 beispielsweise der erste Bereich:
J8:Y8
und in Zelle B2 der Blattname:Sheet3
- In Zelle A3 beispielsweise der zweite Bereich:
G8:AC8
und in Zelle B3 der Blattname:Sheet4
Das Beste an diesem Code ist, dass Sie die nächsten Zeilen hinzufügen können, wenn Sie mehr Bereiche/Blätter zum Durchsuchen haben.
Es wird so aussehen:
Führen Sie nun das Makro aus. Nach der Ausführung werden die Ergebnisse angezeigt aufTabelle 2, zeigt den Namen der Datei und die Anzahl der leeren Zellen in jedem Bereich.
Sub foldersearch()
Dim wbk As Workbook
Dim wbk1 As Workbook
Dim wks As Worksheet
Dim wks2 As Worksheet
Dim totaltime As Long
Dim dtDuration As Date
Set wbk = ThisWorkbook
Set wks = wbk.Sheets(1)
Set wks2 = wbk.Sheets(2)
starttime = Now()
wks2.Cells.ClearContents
dirPath = wks.Cells(1, 1)
file = Dir(dirPath)
rowscounter = 0
Application.ScreenUpdating = False
While (file <> "")
If InStr(file, "xls") > 0 Then
rowscounter = rowscounter + 1
totalpath = dirPath & file
Set wbk1 = Workbooks.Open(totalpath, , True)
rangelist = True
i = 2
columnscounter = 2
While rangelist = True
thenewrango = wks.Cells(i, 1)
thenewsheet = wks.Cells(i, 2)
emptycount = workbooksearch(wbk1, thenewsheet, thenewrango)
wks2.Cells(rowscounter, 1) = file
wks2.Cells(rowscounter, columnscounter) = emptycount
i = i + 1
columnscounter = columnscounter + 1
If wks.Cells(i, 1) = "" Then
rangelist = False
End If
Wend
wbk1.Close (False)
End If
file = Dir
Wend
Application.ScreenUpdating = True
endtime = Now()
totaltime = DateDiff("s", starttime, endtime)
a = MsgBox("Finished in" & vbCrLf & totaltime & " seconds", vbOKOnly)
End Sub
Function workbooksearch(wbk1 As Workbook, wksname As Variant, rango As Variant)
Dim wks1 As Worksheet
Dim obj As Object
On Error GoTo HandleError
Set obj = wbk1.Sheets(wksname)
Set wks1 = wbk1.Worksheets(wksname)
emptycount = 0
For Each c In wks1.Range(rango)
If c.Value = "" Then
emptycount = emptycount + 1
End If
Next c
workbooksearch = emptycount
Exit Function
HandleError:
workbooksearch = "N/A"
End Function