Löschen eines neuen E-Mail-Entwurfs, den Sie in Outlook bearbeiten

Question

Ich verwende Outlook 2013. Wenn Sie eine neue E-Mail verfassen, gibt es normalerweise eine Möglichkeit, diese schnell zu löschen, falls Sie die E-Mail nicht mehr senden möchten. Gibt es eine Möglichkeit, dies in Outlook zu tun?

Ich habe versucht, die Nachricht zu schließen (und nicht zu speichern/aufzubehalten, als ich dazu aufgefordert wurde), aber dadurch wird ein neues ungelesenes Element in meinem Ordner für gelöschte Elemente erstellt, wodurch dieser wie ein Weihnachtsbaum leuchtet. Ich muss dann manuell in diesen Ordner gehen, um den Entwurf zu bereinigen.

Ich suche nach etwas wie dem Papierkorbsymbol von Gmail. Eine einfache und schmerzlose Möglichkeit, die Nachricht mit nur einem Klick ein für alle Mal loszuwerden. (Manchmal möchte ich einen Entwurf speichern – nur für den Fall –, aber meistens tue ich das nicht.)

UPDATE: Sie können oben in der Symbolleiste für den Schnellzugriff eine Schaltfläche „Löschen“ anzeigen, mit der das Nachrichtenelement gelöscht wird. Dies funktioniert, wenn Sie gerade mit dem Schreiben einer neuen E-Mail begonnen haben. Wenn Sie auf Löschen klicken, wird die Nachricht nach der obligatorischen Warnung gelöscht. Aber (!), sobald die E-Mail automatisch gespeichert wird (nach einiger Zeit), wird sie in den Ordner „Entwürfe“ verschoben. Wenn Sie die Nachricht an dieser Stelle löschen, bleibt sie erhalten, da sie lediglich in „Gelöschte Elemente“ verschoben wird.

Gibt es eine Einstellung, mit der Outlook beim Erstellen einer neuen E-Mail die Papierkorb-Schaltfläche von Gmail nachahmen kann? Es ist ein so einfacher Anwendungsfall: „Ich möchte die E-Mail, die ich gerade begonnen habe, nicht senden, habe es mir anders überlegt, möchte sie löschen und alle Spuren davon löschen.“ Ist das ein weiterer Mangel einer Microsoft-Funktion?

Answer 1

1. Sie können ein VBA-Skript schreiben, das etwa Folgendes tut:Verwerfenindem Sie Nachrichten als gelesen markieren und entfernen, umGelöschte Elemente. Platzieren Sie anschließend die Schaltfläche im Nachrichtenfenster, das das Makro ausführt (über „Menüband anpassen“ -> „Makros“).

Etwas wie das:

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            objItem.UnRead = False
            objItem.Delete
        End If
    End If
End Sub

2. FreiQuick Tweaks-Add-Inkann alle gelöschten Elemente automatisch als gelesen markieren.
3. SHIFT+ DELlöscht ausgewählte Nachrichten aus der Nachrichtenliste, ohne sie zu platzierenGelöschte Elemente.

Answer 2

Ich habe eine Möglichkeit gefunden, die Elemente, die dem gelöschten Ordner hinzugefügt werden, automatisch als gelesen zu markieren. Mit dieser Lösung ist es nicht notwendig, eine Schaltfläche hinzuzufügen, die mit einem Makro verknüpft ist.

Fügen Sie dazu im VBA-Editor einfach folgenden Code zu „ThisOutlookSession“ hinzu:

Private WithEvents deletedItems As Outlook.Items

Private Sub Application_Startup()
    Dim olApp As Outlook.Application
    Dim objNS As Outlook.NameSpace
    Set olApp = Outlook.Application
    Set objNS = olApp.GetNamespace("MAPI")
    'Default folder for deleted items
    Set deletedItems = objNS.GetDefaultFolder(olFolderDeletedItems).Items
End Sub

Private Sub deletedItems_ItemAdd(ByVal Item As Object)
    Dim deletedEmail As Outlook.MailItem
    If TypeName(Item) = "MailItem" Then
        Set deletedEmail = Item
        deletedEmail.UnRead = False
    End If
End Sub

Sie müssen Outlook neu starten, damit es funktioniert.

Beachten Sie, dass dies für alle gelöschten E-Mails und nicht nur für die Entwürfe gilt.

Answer 3

Die aktuelle Version von Outlook verfügt in der Mitte des rechten Fensterrands über eine Reihe von Aktionsschaltflächen und darin befindet sich ein rotes X zum Verwerfen.

Ich stimme zu, dass die Benutzeroberfläche von Outlook ziemlich schrecklich und nicht intuitiv ist, aber es sollte nicht nötig sein, Makros zu erstellen, nur um einen Nachrichtenentwurf zu verwerfen.

Answer 4

Die Version, die ich letztendlich verwendet habe, verfügt über Code zum Entfernen des E-Mail-Elements aus „Gelöschte Elemente“ nach dem Löschen.

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            'no EntryID exists for freshly created mail, but does for a draft
            MyEntryId = objItem.EntryID
            objItem.UnRead = False
            objItem.Delete
            If Not MyEntryId = "" Then
                Dim oDeletedItems As Outlook.Folder
                'Obtain a reference to deleted items folder
                Set oDeletedItems = Application.Session.GetDefaultFolder(olFolderDeletedItems)
                'Delete last item from Deleted Items
                oDeletedItems.Items.Item(oDeletedItems.Items.Count).Delete
            End If
        End If
    End If
End Sub