☰

Entfernen Sie ein Laufwerk aus Win 10

tag-icon • tag-icon windows-10 onedrive
Entfernen Sie ein Laufwerk aus Win 10

Ich verwende Amazon Cloud und möchte One Drive lieber nicht auf meinem Computer aktiviert haben. Außerdem möchte ich aus Gründen der Übersichtlichkeit auch das Symbol usw. entfernen. Allerdings (und das ist nicht überraschend) scheint MSFT dies nicht zu einer einfachen Aufgabe gemacht zu haben. Weiß jemand, wie das geht? Vielleicht über die Registrierung?

Antwort1

ich fandein Skript auf einer deutschen Website. Kopieren Sie diesen Text in eine TXT-Datei, benennen Sie sie in RemoveOneDrive.cmd um und führen Sie diesen Befehl als Administrator aus:

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

Dadurch werden zunächst die OneDrive-Prozesse beendet, diese entfernt und die Einträge aus dem Windows Explorer entfernt.

verwandte Informationen