Füllen Sie die Tabelle mit Dateien innerhalb eines Ordners

Question

Ich muss viele Dateien in einem Ordner verwalten, der mit einem Projekt in Zusammenhang steht. Im Moment befinden sich diese Dateien in Dropbox. Ich möchte also eine Möglichkeit finden, wie ich eine Tabelle mit den Namen der Dateien im Ordner füllen kann. Auf diese Weise kann ich Spalten mit Kommentaren, Daten, Status usw. zu diesen Dateien hinzufügen und leicht verwalten, welche bestimmte Bedingungen erfüllen, um sie für die nächsten Schritte vorzubereiten.

Es kann vorkommen, dass auch Dateien zum Ordner hinzugefügt oder daraus entfernt werden.

Gibt es eine Möglichkeit, dies über Excel oder vielleicht Google Spreadsheet zu erreichen? Es ist kein Problem, wenn das Datei-Repository Dropbox, OneDrive, Google Drive usw. ist, solange es eine Freigabeoption gibt.

Danke,

Answer 1

Zwei schnelle Möglichkeiten für den Einstieg (Sie möchten diese wahrscheinlich erweitern, um die Aktualisierung zu vereinfachen).

Mit CMD und dem DIR-Befehl können Sie schnell eine Basisliste der Dateien erstellen, mit denen Sie arbeiten können. Verwenden Sie den folgenden Befehl:

dir /b > output.csv

Alternativ (da Sie die Liste aktualisieren und damit arbeiten möchten) habe ich ein kurzes VBA-Beispiel zusammengestellt. Natürlich müssen Sie möglicherweise Änderungen vornehmen, aber hier ist eine Grundlage:

Sub PopulateRows()
    Dim objFSO, objFolder, colFiles, objFile, FindValue
    Set objFSO = CreateObject("Scripting.FileSystemObject")

    Set objFolder = objFSO.GetFolder("C:\Users\Jonno\Dropbox\Public")
    Set colFiles = objFolder.Files

    Dim curRow

    curRow = FindFirstEmptyRow

    For Each objFile In colFiles
        Set FindValue = Range("A:A").Find(objFile.Name)
        If FindValue Is Nothing Then
            Range("A" & curRow).Value = objFile.Name
            Range("B" & curRow).Value = objFile.Size
            Range("C" & curRow).Value = objFile.DateCreated
            Range("D" & curRow).Value = objFile.DateLastModified
            curRow = curRow + 1
        End If
    Next
End Sub

Function FindFirstEmptyRow()
    Dim curRow
    curRow = 1
    Do
        If IsEmpty(Range("A" & curRow).Value) Then
            FindFirstEmptyRow = curRow
            Exit Function
        End If
        curRow = curRow + 1
    Loop
End Function

Das sind Dateiname, Größe, Erstellungsdatum und Änderungsdatum.

Beachten Sie, dass VBA zwar neue Dateien hinzufügt, derzeit jedoch über keine Logik zum Entfernen von Elementen verfügt. Sie müssen es daher möglicherweise ändern, wenn Sie es verwenden.

Ich bin nicht sicher, ob das für Sie von Nutzen ist, aber ich hoffe, es gibt Ihnen einige Ideen.