☰

Die Eingabetaste kann nicht zum Ausführen von Befehlen in zsh verwendet werden

tag-icon • tag-icon ubuntu zsh xterm gnome-terminal
Die Eingabetaste kann nicht zum Ausführen von Befehlen in zsh verwendet werden

Ich habe vor Kurzem zsh (v5.1.1) auf einem neuen Ubuntu-Setup installiert, aber wenn ich im Gnome-Terminal darauf umschalte, kann ich scheinbar nicht die Eingabetaste verwenden, um den Befehl auszuführen. Ich kann Befehle nur mithilfe von ausführen CTRL+J. Ich kann dies auf anderen Term-Emulatoren wie xtermund replizieren uxterm.

Alle anderen Tasten funktionieren einwandfrei, einschließlich der Tasten Home, End, Bild auf, Bild ab, Entf und Einfg.

Ich habe es zshschon so oft auf anderen Systemen installiert, aber noch nie zuvor ist mir ein solches Problem begegnet. Was muss ich ändern, damit die Eingabetaste normal funktioniert?

Meine /etc/zsh/zshrcDatei:

typeset -ga debian_missing_features

if [[ -z "$DEBIAN_PREVENT_KEYBOARD_CHANGES" ]] &&
[[ "$TERM" != 'emacs' ]]
then

    typeset -A key
    key=(
        BackSpace  "${terminfo[kbs]}"
        Home       "${terminfo[khome]}"
        End        "${terminfo[kend]}"
        Insert     "${terminfo[kich1]}"
        Delete     "${terminfo[kdch1]}"
        Up         "${terminfo[kcuu1]}"
        Down       "${terminfo[kcud1]}"
        Left       "${terminfo[kcub1]}"
        Right      "${terminfo[kcuf1]}"
        PageUp     "${terminfo[kpp]}"
        PageDown   "${terminfo[knp]}"
    )

    function bind2maps () {
        local i sequence widget
        local -a maps

        while [[ "$1" != "--" ]]; do
            maps+=( "$1" )
            shift
        done
        shift

        sequence="${key[$1]}"
        widget="$2"

        [[ -z "$sequence" ]] && return 1

        for i in "${maps[@]}"; do
            bindkey -M "$i" "$sequence" "$widget"
        done
    }

    bind2maps emacs             -- BackSpace   backward-delete-char
    bind2maps       viins       -- BackSpace   vi-backward-delete-char
    bind2maps             vicmd -- BackSpace   vi-backward-char
    bind2maps emacs             -- Home        beginning-of-line
    bind2maps       viins vicmd -- Home        vi-beginning-of-line
    bind2maps emacs             -- End         end-of-line
    bind2maps       viins vicmd -- End         vi-end-of-line
    bind2maps emacs viins       -- Insert      overwrite-mode
    bind2maps             vicmd -- Insert      vi-insert
    bind2maps emacs             -- Delete      delete-char
    bind2maps       viins vicmd -- Delete      vi-delete-char
    bind2maps emacs viins vicmd -- Up          up-line-or-history
    bind2maps emacs viins vicmd -- Down        down-line-or-history
    bind2maps emacs             -- Left        backward-char
    bind2maps       viins vicmd -- Left        vi-backward-char
    bind2maps emacs             -- Right       forward-char
    bind2maps       viins vicmd -- Right       vi-forward-char

    # Make sure the terminal is in application mode, when zle is
    # active. Only then are the values from $terminfo valid.
    if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
        function zle-line-init () {
            emulate -L zsh
            printf '%s' ${terminfo[smkx]}
        }
        function zle-line-finish () {
            emulate -L zsh
            printf '%s' ${terminfo[rmkx]}
        }
        zle -N zle-line-init
        zle -N zle-line-finish
    else
        for i in {s,r}mkx; do
            (( ${+terminfo[$i]} )) || debian_missing_features+=($i)
        done
        unset i
    fi

    unfunction bind2maps
fi # [[ -z "$DEBIAN_PREVENT_KEYBOARD_CHANGES" ]] && [[ "$TERM" != 'emacs' ]]

zstyle ':completion:*:sudo:*' command-path /usr/local/sbin \
                                        /usr/local/bin  \
                                        /usr/sbin       \
                                        /usr/bin        \
                                        /sbin           \
                                        /bin            \
                                        /usr/X11R6/bin

(( ${+aliases[run-help]} )) && unalias run-help
autoload -Uz run-help

# If you don't want compinit called here, place the line
# skip_global_compinit=1
# in your $ZDOTDIR/.zshenv or $ZDOTDIR/.zprofile
if [[ -z "$skip_global_compinit" ]]; then
autoload -U compinit
compinit
fi

Antwort1

Um das Zeichen auszugeben, das zsh jedem Schlüssel zuordnet, geben Sie ⌃+ vund dann das Zeichen ein (wobei ⌃der CtrlSchlüssel ist).

Zum Beispiel:

  • meine Return-Taste gibt aus:^M
  • meine Eingabetaste gibt aus:^[OM

So verhält sich meine Eingabetaste wie meine Return-Taste:

bindkey '^[OM' accept-line

verwandte Informationen