Excel-Formel für Duplikate

Question

Könnte mir jemand freundlicherweise die Formel zeigen, die ich brauche, um genau die Daten zu erstellen, die ich in Spalte C habe:

Alle doppelten Zellen in Spalte B kopieren die SKU aus Spalte A in Spalte C.

Hoffe, ich habe das richtig erklärt!!

Answer 1

Wenn Sie nicht über Office 365 Excel verfügen, benötigen Sie eine UDF. Fügen Sie diesen Code in ein an die Arbeitsmappe angehängtes Modul ein:

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then 
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
    Else
        TEXTJOIN = ""
    End IF
End Function

Dann erledigt die folgende Array-Formel das Gewünschte:

=TEXTJOIN(" | ",TRUE,IF($A$2:$A$11<>A2,IF($B$2:$B$11=B2,$A$2:$A$11,""),""))

Da es sich um eine Array-Formel handelt, muss sie beim Verlassen des Bearbeitungsmodus mit Strg-Umschalt-Eingabe statt mit der Eingabetaste bestätigt werden. Wenn dies richtig gemacht wird, wird Excel {}die Formel umschließen.

---

Wenn Sie Office 365 Excel haben, verwenden Sie die obige Formel einfach als Array-Formel, die UDF ist nicht erforderlich.

Die UDF ahmt die Funktionalität von TEXTJOIN nach.