☰

Batch-Skript zum Auflisten aller Dateien auf der Festplatte

tag-icon • tag-icon windows command-line batch
Batch-Skript zum Auflisten aller Dateien auf der Festplatte

Ich möchte eine kleine Batchdatei erstellen, die mir alle auf einer Datei gespeicherten Daten auflistet. Der Befehl lautet:

TREE L: / F / A> List.txt

Ich möchte aber, dass der Benutzer den zu verarbeitenden Laufwerksbuchstaben eingibt und das Ergebnis in eine Datei mit dem Namen und dem aktuellen Datum geschrieben wird. Beispiel:

C:\> makelist.bat
Please, insert the drive letter: L
Done!

Das Ergebnis muss in eine Datei mit dem Namen z.B. eingetragen List_2017-03-13.txtund auf den Desktop verschoben werden

Welche Befehle sollte ich zum Erstellen des Skripts verwenden?

Antwort1

Der folgende Batch verwendet wmic, um

  • Holen Sie sich ein von Ort und Benutzereinstellungen unabhängiges Datum
  • Holen Sie sich eine Liste der verfügbaren Laufwerksbuchstaben
  • und Möglichkeit, einen Buchstaben auszuwählen
:: makelist.bat
@Echo off&SetLocal EnableExtensions EnableDelayedExpansion
set Started=%date% %time%
:: get locale/user-settings independent date
for /f "delims=." %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set "DT=%%A"
Set MyDate=%DT:~0,4%-%DT:~4,2%-%DT:~6,2%

:: gather available drives
Set "Drives="
FOr /f "delims=:" %%A in (
  'Wmic logicaldisk get name^|findstr "^[A-Z]:"'
) DO Set "Drives=!Drives!%%A"

:: choose drive letter
Choice /C %Drives% /M "Select drive letter for tree"
Set /A "Inp=%Errorlevel%,Pnt=Inp-1"
IF %Inp% equ 0   Echo aborted & pause & exit /B 1
If %Inp% equ 255 Echo aborted & pause & exit /B 1
Set "Drive=!Drives:~%Pnt%,1!"

:: do the tree 
Echo %Started% Tree started
Echo Tree %Drive%:\ /F /A  "%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
     Tree %Drive%:\ /F /A >"%UserProfile%\Desktop\Tree_%Drive%_%MyDate%.txt"
Echo %date% %time% done
timeout -1

Beispieldialog:

Select drive letter for tree [C,D,E,G,H,K,M,N,P,Q,R,T,U,V,W,X,Z]?H
2017-03-13 14:17:05,45 Tree started
Tree H:\ /F /A "C:\Users\UserName\Desktop\Tree_H_2017-03-13.txt"
2017-03-13 14:17:13,70 done

Drücken Sie eine beliebige Taste, um den Vorgang fortzusetzen...

Antwort2

tree2txt.bat:

@tree %1 / F / A > Tree_%1_%date.TxT

Verwendung: tree2txt X:

Ergebnis: Baum des Laufwerks X:\ in eine Datei mit dem Namen Tree_X_20170313.TxT

Beachten Sie, dass das Ausgabeformat des Datums von Ihren lokalen Datumsformateinstellungen abhängt (yyyy-mm-dd und die anderen Formate).

verwandte Informationen