
Im Windows Explorer die EinstellungVersteckte Dateien, Ordner und Laufwerke anzeigenkann unter aktiviert und deaktiviert werden Organise > Folder and search options > View
.
Gibt es eine andere, schnellere Möglichkeit, diese Einstellung zu aktivieren/deaktivieren? Etwas über die Befehlszeile wäre ideal, aber ich bin für alle Vorschläge offen, die schneller oder weniger umständlich sind.
Antwort1
Diese Einstellungen finden Sie in der Registrierung unter diesem Schlüssel:
HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced
Um versteckte Elemente anzuzeigen, setzen Sie den Wert Hidden
auf 1 (um sie zu verbergen, setzen Sie den Wert auf 2). Um System-/superversteckte Elemente anzuzeigen, setzen Sie den Wert ShowSuperHidden
auf 1 (um sie zu verbergen, setzen Sie den Wert auf 0). Da wir direkt an der Registrierung herumfummeln, muss der Explorer neu gestartet werden.
Um all dies zu erreichen und die Anzeige aller Daten zu ermöglichen, können Sie die folgenden Batch-Befehle verwenden:
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Hidden /t REG_DWORD /d 1 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSuperHidden /t REG_DWORD /d 1 /f
powershell -c gps 'explorer' ^| stop-process
Wenn Sie PowerShell lieber vermeiden möchten, können Sie den Explorer auch folgendermaßen beenden:
taskkill /im explorer.exe /f
Wenn der Explorer auf Ihrem System nicht automatisch neu gestartet wird, führen Sie ihn einfach aus, explorer
um Ihre Taskleiste wiederherzustellen.
Antwort2
Ich beschloss, die von Ben bereitgestellten Tasten und Befehle zu nehmen und eine einzelne Batchdatei zu schreiben, die die Werte Hidden
und ShowSuperHidden
gemeinsam ein- oder ausschaltet.
Umschalten zwischen versteckten und superversteckten Dateien mit einer Batchdatei
Du kannstLaden Sie ToggleHidden.bat hier herunter.bat
, aber wenn Sie das Skript lieber selbst in eine Datei kopieren möchten .cmd
, finden Sie hier den Quellcode:
@echo off
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" | Find "0x0"
If %ERRORLEVEL% == 0 goto show
IF %ERRORLEVEL% == 1 goto hide
goto :error
:show
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 1 > NUL
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 1
goto restart
:hide
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 0 > NUl
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 0
goto restart
:error
echo There was an error! Check the script.
pause
goto :eof
:restart
taskkill /f /im explorer.exe
start explorer
Eine Aufschlüsselung dessen, was das Skript macht: Es fragt die Daten des Hidden
Werts ab; wenn es ausgeschaltet ist, schaltet es es ein und ShowSuperHidden
aus. Wenn es bereits eingeschaltet ist, schaltet es es ein und ShowSuperHidden
aus. Ich habe mich entschieden, das Skript auf diese Weise zu gestalten, weil es selten vorkommt, dass ich persönlich versteckte Dateien sehen muss, ohne auch Systemdateien zu sehen, aber Sie können dieses Verhalten ändern, wenn Sie möchten. 1
Nachdem diese Registrierungswerte aktiviert oder deaktiviert wurden, beendet das Skript den Windows Explorer-Explorer-Prozess und startet ihn neu. Wenn der Wert aus irgendeinem Grund Hidden
nicht durch den Befehl ermittelt werden kann query
, bricht das Skript ab und gibt einen Fehler aus, bevor es beendet wird.
Zuordnen der Batchdatei zu einem Hotkey
Um meinen Kriterien für maximale Benutzerfreundlichkeit gerecht zu werden, habe ich die neu erstellte ToggleHidden.bat
Datei irgendwo auf meinem Computer abgelegt und verwendetAutoHotKeyum eine Hotkey-Kombination zum Ausführen zuzuordnen. Dazu habe ich meinem bestehenden AHK-Skript Folgendes hinzugefügt:
Ctrl & H::
Run PATH\TO\FILE
Return
Ich habe hier AutoHotKey verwendet, da ich es bereits für ähnliche Zwecke verwende und es für die nützlichere Methode zum Zuweisen von Hotkeys zum Ausführen meiner Programme halte. Wenn Sie für diesen Schritt jedoch lieber nicht AHK installieren möchten, können Sie auchdiese native Windows-Methode zum Zuweisen von Hotkeys zu einem Programm.
CtrlIch kann jetzt die Hotkey-Kombination + verwenden, Hum versteckte/Systemdateien nach Belieben auszublenden und schnell anzuzeigen oder auszublenden … und es funktioniertschön, wenn ich es sage.
1 Wenn Sie diesen Weg einschlagen möchten, sollten Sie beachten, dass superversteckte Dateien/Ordner im Windows-Ökosystem als Teilmenge der versteckten Dateien/Ordner fungieren.
Das bedeutet im Hinblick auf diese beiden Registrierungswerte, dass Sie den Hidden
Wert aktivieren können, ohne zu aktivieren ShowSuperHidden
, aber nicht aktivieren, ShowSuperHidden
ohne zu aktivieren Hidden
. Wenn Sie dies tun, werden Ihnen nur normale Elemente angezeigt, da Windows extrem ausgeblendete Elemente als eine Art verstecktes Element betrachtet, und wenn versteckte Elemente versteckt sind, sind es auch extrem ausgeblendete Elemente. Einfach ausgedrückt: Wenn Sie vorhaben zu aktivieren ShowSuperHidden
, müssen Sie sicherstellen, dass Sie Hidden
gleichzeitig aktivieren.
Antwort3
Die Option „Versteckte Ordner anzeigen“ ist speziell Teil des Explorers.
attrib
Obwohl Sie in der Befehlszeile die Befehle oder verwenden können, dir /ah
um versteckte Dateien anzuzeigen, können Sie die versteckten Einstellungen nicht über die Befehlszeile steuern, es sei denn, Sie gehen vorher ziemlich lange durch. Im Wesentlichen wird diese Einstellung in der Registrierung gespeichert und Sie können die Registrierung über die Befehlszeile ändern. Dieser Weg ist jedoch weitaus umständlicher, als die Einstellung schnell im Explorer zu ändern.
Wenn Sie dies häufig tun, ist es schneller, die Einstellung in der Registrierung zu finden und in einer REG-Datei zu speichern, weil Sie sie dann durch Doppelklicken auf die beiden REG-Dateien aktivieren bzw. deaktivieren können.
Leider weiß ich nicht, wo in der Registry es liegt. Ich weiß nur, dass es im HKCU-Hive ist, aber nicht wo genau.
Wenn Sie auf Windows 10 aktualisieren, finden Sie diese Einstellung direkt auf der Registerkarte „Ansicht“.
Antwort4
Durch die Verwendung einer Freeware und eine leichte Änderung des Skripts kann ich nun versteckte Dateien ein- und ausblendenUndalle Explorer-Ordnerfenster wiederherstellen, die ich geöffnet hatte.
Laden Sie zunächst die Freeware-App hier herunter:
https://www.sordum.org/9192/restart-explorer-v1-4/
extrahieren und verschieben Sie den gezippten Rexplorer-Ordner nachC:\Programme
Nehmen Sie dann die folgende Änderung am obigen Batch-Skript vor:
:restart
start "" "C:\Program Files\Rexplorer\Rexplorer_x64.exe"
exit
Dies führt dazu, dass die App Rexplorer_x64.exe explorer.exe neu startet und alle geöffneten Ordner wiederherstellt, anstatt den Explorer einfach zu beenden und neu zu starten.