☰

Microsoft Excel, mehrere Formeln in einer Zelle

tag-icon • tag-icon microsoft-excel
Microsoft Excel, mehrere Formeln in einer Zelle

Ich bräuchte bitte Hilfe beim Einfügen mehrerer Formeln in eine Zelle.

Wenn ich beispielsweise 1 in g11 eingebe, soll die folgende Formel verwendet werden: =if(H11="","",I11/(230*H11))

Wenn ich beispielsweise 3 in g11 eingebe, soll die folgende Formel verwendet werden: =if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

Dank im Voraus

Antwort1

Sie können dieselbe WENN-Funktion auch zum Testen der Zelle G11 verwenden: (verwenden Sie diese Formel in einer einzigen Zeile)

=if(G11=1,  
    if(H11="","",I11/(230*H11)), 
    if(G11=3, 
            if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),
            ""
      )
   )

=if(G11=1,um zu testen, ob der Wert 1 ist.
        if(H11="","",I11/(230*H11)),Bedingung „Wahr“: Führen Sie Ihre Formel für 1 aus.
        if(G11=3,Wenn es „Falsch“ war, testen Sie den Wert für 3.
              if(H11="","",I11/(sqrt(3)*400*H11*(E11/100))),Wenn G11 3 ist, führen Sie Ihre zweite Formel aus.
              ""Wenn G11 etwas anderes ist, tun Sie nichts.
      )Schließen Sie, wenn (G11=3,,)
)Schließen Sie, wenn (G11=1,,)

Antwort2

Wie wäre es mit

 =IF(G11=1,IF(H11="","",I11/(230*H11)),IF( G11=3,IF(H11="","",I11/(SQRT(3)*400*H11*(E11/100))),""))

Antwort3

Sicherlich ist Ihnen aufgefallen, dass Ihre beiden (optionalen) Formelnsehrähnlich:

=if(H11="","",I11/(230        *H11          ))
 ↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕↕           ↕↕↕↕          ↕↕
=if(H11="","",I11/(sqrt(3)*400*H11*(E11/100)))

und Sie können die zweite Formel umstellen, um sie zu vereinfachen und die Ähnlichkeit zu erhöhen:

 400*H11*(E11/100)
=400*(E11/100)*H11
=(400*E11/100)*H11
=(E11*400/100)*H11
=E11*(400/100)*H11
=E11 *   4   * H11
=4*E11*H11

Ihre zweite Formel reduziert sich also auf

=if(H11="","",I11/(sqrt(3)*4*E11*H11))

Wir können diese Ähnlichkeit nutzen, um die Gesamtformel (die in einigen anderen Antworten gegeben wurde) zu vereinfachen und

=if(H11="","",I11/(IF(G11=1,230,IF(G11=3,sqrt(3)*4*E11,0))*H11))

Beachten Sie, dass bei G11einem anderen Wert als 1 oder 3 explizit eine Division durch 0 erfolgt, was zu einem Fehler führt. Verwenden Sie diese Antwort nicht, wenn dies ein Problem für Sie darstellt.

verwandte Informationen