ID basierend auf dem Namen erstellen

Question

Ich habe eine große Anzahl von Kundennamen, für die ich eindeutigen Code erstellen muss.

Ich möchte die ersten 4 Buchstaben des 1. Wortes, die ersten 3 Buchstaben des 2. Wortes und die ersten 2 Buchstaben des 3. Wortes verwenden.

4 EVEREST YOUNG
ABIC INVESTMENTS PTY. LTD. 

Die eindeutige ID würde also folgendermaßen aussehen:

4eveyo
abicinvpt

Könnte mir jemand mit einer Formel weiterhelfen, mit der dies erreicht werden könnte?

Vielen Dank im Voraus.

Answer 1

Angenommen, Ihre Daten befinden sich in der Zelle A1, versuchen Sie Folgendes:

=LEFT(A1,MIN(FIND(" ",A1)-1,4)) & MID(A1,FIND(" ",A1)+1,MIN(3,FIND(" ",A1,FIND(" ",A1)+1)-FIND(" ",A1))) & MID(A1,FIND(" ",A1,FIND(" ",A1)+1)+1,MIN(2,LEN(A1)-FIND(" ",A1,FIND(" ",A1)+1)))

Answer 2

Dadurch werden kurze Wörter verarbeitet, ohne dass im Ergebnis Fehler oder Leerzeichen auftreten.

=IF(ISERROR(FIND(" ",G624)),LEFT(G624,4),TRIM(LEFT(G624,MIN(4,FIND(" ",G624))))&TRIM(MID(G624,FIND(" ",G624)+1,MIN(3,IF(ISERROR(FIND(" ",G624,FIND(" ",G624)+1)),3,FIND(" ",G624,FIND(" ",G624)+1))-FIND(" ",G624))))&IF(ISERROR(FIND(" ",G624,FIND(" ",G624)+1)),"",TRIM(MID(G624,FIND(" ",G624,FIND(" ",G624)+1)+1,2))))

Was für ein Monster.

Beispiele:

4 EVEREST YOUNG               4EVEYO
ABIC INVESTMENTS PTY. LTD.    ABICINVPT
ABCDE FGIJK LMNOP QRSTU       ABCDFGILM
ABCDEFG I I I I               ABCDII
ABCDEFG                       ABCD
A                             A
A B                           AB
A B C                         ABC
A B C D                       ABC
AB CD EF GH                   ABCDEF
ABC DEF GHI JKL               ABCDEFGH

Bearbeiten: Bei meinem ersten Versuch trat ein Problem auf, als ich weitere Beispiele hinzufügte.