Ein Hotkey zum Verschieben einer Datei durch Verzeichnisse (MacOS)

Question

Gibt es Hotkeys zum Verschieben von Ordnern nach oben oder unten durch übergeordnete Ordner und Unterordner in MacOS?

In diesem einfachen Beispiel möchte ich beispielsweise die Datei 1234.pdf in Ordner A verschieben, wodurch Unterordner A leer bleibt. Im Idealfall kann ich dies nur mit der Tastatur tun. Bonuspunkte: Ein Hotkey zum erneuten Auswählen des zuletzt ausgewählten Unterordners (damit ich ihn löschen, umbenennen usw. kann).

- Folder A
   - Subfolder A
      -File 1234.pdf 
- Folder B

Answer 1

Ich entschuldige mich für die Verzögerung bei meiner Antwort. Es war schwieriger, als ich erwartet hatte.

Aber es ist möglich, das zu erreichen, was Sie wollen, indem Sie eineServiceInAutomator, die dann über eine Tastenkombination (Hotkey) zugänglich wird.

Sie müssen folgendiese Anleitung zum Einrichten eines systemweiten Dienstes.

---

Erstellen Sie zunächst einen neuen Dienst inAutomator. Es muss erhaltenDateien oder Ordnerals Input und zur Verfügung gestellt inFinder.

Füge hinzu einAppleScript ausführenAktion zum Workflow hinzufügen. Im Textbereich dieser Aktion kann das folgende AppleScript kopiert und eingefügt werden:

    use Finder : application "Finder"

    property F_ : missing value -- The previous folder
    property f : missing value -- The files that we moved
    property home : Finder's home as alias


    on run {f, _}
      get its ParentFolderOf:(some item in f)
      set there to the result -- The destination folder, one level up

      -- We won't navigate any higher up the folder tree than
      -- the home folder
      if (its ParentFolderOf:home) is in there then return

      -- Also don't apply this service to other folders that aren't
      -- in the same branch of the folder tree as the home folder
      if (there as text) does not begin with (home as text) then return

      -- The folder we're currently at
      tell Finder to set F_ to ¬
        (the container of some item in f) as alias

      -- Check to ensure there are no files in the destination folder
      -- that risk being overwritten.  If there are, we won't move
      -- the files who share the same name, i.e. only move those that 
      -- are safe to move.
      tell Finder to ¬
        repeat with _g in f
          get name of _g
          set g to [there as text, result] as text
          if not (g exists) then set end of f to _g
          set f to the rest of f
        end repeat

      -- Move the files
      tell Finder ¬
        to set f ¬
        to (move f to there) ¬
        as list as alias list

      -- Reveal them
      reveal f
      activate Finder
    end run


    to ParentFolderOf:(f as alias)
      local f

      set F_ to [f, "::"] as text as alias

      if (f as text) ends with ":" then return F_

      return its ParentFolderOf:F_
    end ParentFolderOf:

Speichern Sie den Dienst unter einem beliebigen Namen. Automatorspeichert es automatisch am richtigen Ort (~/Bibliothek/Dienste). Ich habe meine gespeichert als„Im Finder aufsteigen“.

Als nächstes müssen Sie eine Tastenkombination erstellen. Dies geschieht durchSystemeinstellungen:

Scrollen Sie in der Liste der Dienste nach unten zum Abschnitt mit der MarkierungDaten und Ordner, unter dem Ihr Dienstname erscheinen sollte. Sie können meinen hervorgehoben sehen. Ich habe die Verknüpfung ⌃▲für meinen erstellt (Strg+Nach-oben).

Jetzt, jedes Mal, wenn ich Dateien und/oder Ordner auswähle inFinderund drücke ⌃▲, werden diese Dateien und Ordner in der Hierarchie eine Ebene höher in ihren übergeordneten Ordner verschoben. Wenn ich sie zurück verschieben möchte, kann ich drücken, ⌘Zum das Verschieben rückgängig zu machen.

Ich habe eine Sicherheitsvorkehrung eingebaut, damit Dateien und Ordner nicht weiter oben im Ordnerbaum verschoben werden als in Ihren Home-Ordner. Das ist sowieso unwahrscheinlich, dass Sie das brauchen.

Answer 2

Wenn Sie in der Spaltenansicht arbeiten, können Sie nur mit den Pfeiltasten navigieren.

Für Ihr Beispiel: Angenommen, Sie beginnen mit der ausgewählten Datei …

• Cmd ⌘ C Kopieren

• Linker Pfeil [dadurch wird Unterordner A ausgewählt], also für Bonuspunkte …

  • Enter ⌅ ermöglicht Ihnen, die Datei umzubenennen oder Cmd ⌘ Backspace ⌫ zu löschen
    [Dadurch geht die Datei, die sich derzeit im Kopierpuffer befindet, nicht verloren]

• Pfeil nach links [dadurch wird Ordner A ausgewählt]*

• Cmd ⌘ Opt ⌥ V bewegen

Dies ist die Struktur, wie sie am Anfang erscheint.

und nochmal am Ende [nachdem wir im Vorbeigehen den Unterordner A gelöscht hatten]

*Da es in der Antwort nirgends erwähnt wird, würde der Abwärtspfeil an dieser Stelle den Ordner B auswählen