☰

Aufteilen von Daten aus einer Zelle in mehrere in Microsoft Excel 2010 mithilfe eines Doppelpunkts als Trennzeichen

tag-icon • tag-icon microsoft-excel microsoft-excel-2010
Aufteilen von Daten aus einer Zelle in mehrere in Microsoft Excel 2010 mithilfe eines Doppelpunkts als Trennzeichen

Ich möchte die Wörter nach dem Doppelpunkt in neue Spalten zurückziehen, im folgenden Beispiel hätte ich also gerne „Specie“ in B, „jehwejkrhwejkrhwe“ in C, „07/06/2018“ in D, „Kim's Wizard Wand Shop“ in E und „Q18FSESPE00374“ in F. Irgendwelche Ideen?

[ Produkt: Spezies], [ UMR: jehwejkrhwejkrhwe], [EffDt: 07/06/2018], [Insd: Kims Zauberstabladen], [PolNr: Q18FSESPE00374]

Antwort1

=MID(A1,SEARCH(":",A1)+1,LEN(A1)-(SEARCH(":",A1)+1))

Meine Formel muss auf die Daten in jeder Zelle angewendet werden.

Es wäre vielleicht besser, dies auf Blatt2 zu tun und es auf Ihre Daten auf Blatt1 zu verweisen.

Antwort2

Dies kann auf zwei Arten erfolgen.


1 – Mit einer Hilfszeile und zwei einfachen Formeln:

Screenshot der Formel mit Hilfszeile

Die Formel B2lautet:

=FIND(CHAR(1),SUBSTITUTE($A$1,":",CHAR(1),COLUMN()-COLUMN($B:$B)+1))

Und die Formel B3lautet:

=MID($A$1,B2+1,FIND("]",$A$1,B2)-B2-1)


2 – Ohne Hilfszeilen, aber mit einer komplexen Formel:

Screenshot der Formel ohne Hilfszeile

Die Formel B2lautet:

=MID($A$1,FIND(CHAR(1),SUBSTITUTE($A$1,":",CHAR(1),COLUMN()-COLUMN($B:$B)+1))+1,FIND(CHAR(1),SUBSTITUTE($A$1,"]",CHAR(1),COLUMN()-COLUMN($B:$B)+1))-1-FIND(CHAR(1),SUBSTITUTE($A$1,":",CHAR(1),COLUMN()-COLUMN($B:$B)+1)))

Die verschönerte Version der obigen Formel lautet wie folgt:

=
MID(
  $A$1,
  FIND(CHAR(1),SUBSTITUTE($A$1,":",CHAR(1),COLUMN()-COLUMN($B:$B)+1))+1,
  FIND(CHAR(1),SUBSTITUTE($A$1,"]",CHAR(1),COLUMN()-COLUMN($B:$B)+1))-1
  -FIND(CHAR(1),SUBSTITUTE($A$1,":",CHAR(1),COLUMN()-COLUMN($B:$B)+1))
)

Anmerkungen

  • CHAR(1)wurde verwendet, da es fast sicher ist, dass dieses Zeichen nicht in einer Zeichenfolge vorkommt. Es könnte natürlich durch jedes andere Zeichen ersetzt werden, von dem Sie sicher sind, dass es in der Quellzeichenfolge nie vorkommt.

verwandte Informationen