Laufwerke zum Navigationsbereich des Windows-Datei-Explorers hinzufügen

Question

Ich möchte die Laufwerke C: und D: auf die gleiche Weise anzeigen, wie „Dieser PC“ im Navigationsbereich angezeigt wird. Ich kenne den Prozess, den ich durchlaufen muss (siehediese Antwort), weiß jedoch nicht, welchen Registrierungsspeicherort ich bearbeiten soll. Kann mir jemand den Weg zeigen? Wenn möglich, würde ich auch gerne einen bestimmten Ordner innerhalb von D: zum Navigationsbereich hinzufügen.

Ich habe versucht,Lösungbereitgestellt von tenforums, das Hinzufügen der Laufwerke schlug jedoch fehl.

Answer 1

Dank anSimon MourierUndseine Antwort aufEinen Ordner an den Navigationsbereich im Windows Explorer anheften:

PinDiskD.bat. Führen Sie aus, um die Festplatte D:\irgendwo über dem This PCin derDateimanagerNavigationsbereich. Führen Sie es mit einem beliebigen nicht leeren Parameter aus, um die Festplatte D:\aus dem Bereich zu entfernen, z. B. PinDiskD.bat x(beachten Sie die :deleAllBeschriftung unten).

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=d DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%}                                   /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%}                 /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

PinDiskC.bat. Fixiert die Festplatte C:\im Fenster. Dasselbe wiePinDiskD.bataußer vier wichtigsten setBefehlen:

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"
…

D:\bat\PinCodePages.bat. Heftt einen bestimmten lokalen Ordner an den Bereich an. Dasselbe wiePinDiskD.batmit Ausnahme der vier wichtigsten setBefehle (überprüfen Sie die Gültigkeit der Variablen _icon, _name, _guidund doppelt _target):

set "_icon=%%SystemRoot%%\system32\shell32.dll,176" # any valid icon
set "_name=My Folder"                               # any valid name
set "_guid=ffffffff-ffff-ffff-0000-00000000c0de"    # a valid GUID (no braces)
set "_target=d:\Utils\CodePages\\"                  # any valid local path
…

Beispiel, wie es unter Windows 10 aussieht, nachdem alle oben genannten Skripte ausgeführt wurden: