Excel: Liste der installierten Basis

Question

Vielen Dank im Voraus für Ihre Hilfe!
Was würden Sie mir anhand dieser Tabelle raten:

Equipment Desc | Ship To Name
------------------+----------
Small             | Bob
Small             | Dylan
Small             | Joe 
Small             | Ethan
Small             | Bob   
Medium            | Joe
Medium            | Michael
Medium            | Bob    
Big               | Bob   
Big               | Joe
Big               | Michael

Zu dieser Tabelle:

Ship To Name | Equipment Desc
-------------+-------------
Bob          | 1 Big, 1 Medium, 2 small 
Dylan        | 1 Small
Joe          | 1 Big, 1 Medium, 1 Small
Ethan        | 1 Small
Michael      | 1 Big, 1 Medium

Ich habe die PowerQuery-Lösung aus einem älteren Beitrag ausprobiert. https://superuser.com/a/1054653/1136022
Das war mein Eindruck

= Table.Group(#"Changed Type", {"Ship To Name"}, {{"Installed Base", each Text.Combine([Equipment Desc], "#(cr)"), type text}})

Es summiert die Instrumente jedoch nicht. Es gibt nur eine Liste der Instrumente zurück. Es
zeigt also nicht „2 Big“, sondern „1 Big, 1 Big“.

Vielen Dank im Voraus für Ihre Berücksichtigung.

Beste grüße,

Thomas

Answer 1

Damit sollten Sie im Wesentlichen ziemlich nah herankommen:

• Gruppieren nach mit einer Anzahl
• Spalten zusammenführen, um Anzahl und Gerätebeschreibung zu kombinieren
• Pivot auf Gerätebeschreibung
• Spalten zusammenführen

Es sieht so aus, als ob Ihr vorheriger Schritt auch #"Geänderter Typ" hieß, Sie sollten also meinen Code von diesem Punkt aus einfügen können. Es ist immer etwas knifflig, den M-Code von jemand anderem zu integrieren.

let
        Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WCs5NzMlR0lFyyk9SitVB8F0qcxLzUES88lMVUARcSzLQlMAM8U1NySzNRdYDF/HNTM5ITM1BFYTpc8pMx+DBjYBw4fpjAQ==", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type text) meta [Serialized.Text = true]) in type table [#"Equipment Desc" = _t, #"Ship To Name" = _t]),
        #"Changed Type" = Table.TransformColumnTypes(Source,{{"Ship To Name", type text}, {"Equipment Desc", type text}}),
        #"Grouped Rows" = Table.Group(#"Changed Type", {"Ship To Name", "Equipment Desc"}, {{"Count", each Table.RowCount(_), type number}}),
        #"Duplicated Column" = Table.DuplicateColumn(#"Grouped Rows", "Equipment Desc", "Equipment Desc - Copy"),
        #"Merged Columns" = Table.CombineColumns(Table.TransformColumnTypes(#"Duplicated Column", {{"Count", type text}}, "en-AU"),{"Count", "Equipment Desc - Copy"},Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"Merged"),
        #"Sorted Rows" = Table.Sort(#"Merged Columns",{{"Equipment Desc", Order.Ascending}}),
        #"Pivoted Column" = Table.Pivot(#"Sorted Rows", List.Distinct(#"Sorted Rows"[#"Equipment Desc"]), "Equipment Desc", "Merged"),
        #"Merged Columns1" = Table.CombineColumns(#"Pivoted Column",{"Big", "Medium", "Small"},Combiner.CombineTextByDelimiter(", ", QuoteStyle.None),"Equipment Desc")
 in
        #"Merged Columns1"

Answer 2

Hier ist eine Methode:

• Gruppieren nach Beide Spalten mit einemRowCount
• Die Spalten „Equipment“ und „Count“ mithilfe <space>eines Trennzeichens zusammenführen
• Gruppieren nach der Spalte NameAll Rows
• Fügen Sie eine benutzerdefinierte Spalte hinzu, um die resultierende Tabelle in eine Liste umzuwandeln
  • Benutzerdefinierte Spaltenformel:=Table.Column([Equipment],"Merged")
• Extrahieren Sie Werte aus der ListSpalte (mit dem Doppelpfeil) mit ,als Trennzeichen

---

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Equipment Desc", type text}, {"Ship To Name", type text}}),
    #"Trimmed Text" = Table.TransformColumns(#"Changed Type",{{"Ship To Name", Text.Trim, type text}, {"Equipment Desc", Text.Trim, type text}}),
    #"Grouped Rows" = Table.Group(#"Trimmed Text", {"Ship To Name", "Equipment Desc"}, {{"Count", each Table.RowCount(_), type number}}),
    #"Merged Columns" = Table.CombineColumns(Table.TransformColumnTypes(#"Grouped Rows", {{"Count", type text}}, "en-US"),{"Count", "Equipment Desc"},Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"Merged"),
    #"Grouped Rows1" = Table.Group(#"Merged Columns", {"Ship To Name"}, {{"Equipment", each _, type table [Ship To Name=text, Merged=text]}}),
    #"Added Custom" = Table.AddColumn(#"Grouped Rows1", "Eqpt List", each Table.Column([Equipment],"Merged")),
    #"Removed Columns" = Table.RemoveColumns(#"Added Custom",{"Equipment"}),
    #"Extracted Values" = Table.TransformColumns(#"Removed Columns", {"Eqpt List", each Text.Combine(List.Transform(_, Text.From), ", "), type text})
in
    #"Extracted Values"