☰

Outlook VBA - E-Mail-Anhang im Termin öffnen und E-Mail-Adresse des Absenders extrahieren

tag-icon • tag-icon microsoft-outlook vba extract attachments
Outlook VBA - E-Mail-Anhang im Termin öffnen und E-Mail-Adresse des Absenders extrahieren

Ich habe über 200 Kalendereinträge (Termine) und alle enthalten die ursprüngliche E-Mail-Nachricht als Anhang. Ich muss die E-Mail-Adresse des Absenders aus dem E-Mail-Anhang im Termin extrahieren.

Ich weiß, wie man die E-Mail-Adresse des Absenders aus einem MailItem-Objekt () extrahiert MailItem.SenderEmailAddress, aber ich weiß nicht, wie ich auf diese Eigenschaften zugreife, wenn die E-Mail-Nachricht jetzt ein Anhang in einem Termin ist. Das AppointmentItemObjekt hat eine Eigenschaft „Attachments“, aber es sind nirgendwo andere Informationen verfügbar, wie man auf Eigenschaften im Objekt „Attachments“ zugreift. Habe AppointmentItem.Attachments.item(1).SenderEmailAddress ausprobiert und bekam „Objekt nicht unterstützt...“

Antwort1

Sie können den MSG-Anhang speichern, als Mailitem öffnen und dann die Mailitem-Eigenschaft lesen.

Option Explicit ' Consider this mandatory
' Tools | Options | Editor tab
' Require Variable Declaration
' If desperate declare as Variant


Private Sub saveAndRetrievePropertyOfAttachedMail()

    Dim sPath As String
    
    ' the selected item may not be an AppointmentItem
    Dim oItem As Object
    
    sPath = ""
    
    Set oItem = ActiveExplorer.Selection.Item(1)
    
    If TypeName(oItem) = "AppointmentItem" Then
        Debug.Print oItem.subject
        
        ' sPath is initially blank
        ' There are risks with public variables.
        ' This is a slightly awkward way to avoid declaring sPath as a public variable
        saveAttachmentsToDriveFolder oItem, sPath
        
        returnPropertiesOfAttachmentInDriveFolder sPath
        
    End If
    
End Sub


Sub saveAttachmentsToDriveFolder(objItem, strPath)

    Dim fso As Object
    Dim fldTemp As Object
    
    Dim objAtt As Object
    Dim strFile As String
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    ' This is a default folder everyone should have.
    ' You may use another folder.
    ' Kill the files when you are done or delete manually
    Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
    Debug.Print fldTemp
    
    strPath = fldTemp.Path & "\"
    Debug.Print strPath
    
    For Each objAtt In objItem.Attachments
        strFile = strPath & objAtt.FileName
        Debug.Print strFile
        objAtt.SaveAsFile strFile
    Next
    
End Sub


Sub returnPropertiesOfAttachmentInDriveFolder(strAttachmentFolder)

Dim objFileSystem As Object
Dim objFolder As Object
Dim objFiles As Object
Dim objFile As Object
Dim objItem As Object

Set objFileSystem = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFileSystem.GetFolder(strAttachmentFolder)
Set objFiles = objFolder.Files

For Each objFile In objFiles

    If objFileSystem.GetExtensionName(objFile) = "msg" Then
    
        'Open msg file
        Set objItem = Session.OpenSharedItem(objFile.Path)
        Debug.Print objItem.SenderEmailAddress

    End If
Next

End Sub

verwandte Informationen