☰

Bitte erläutern Sie das unten bereitgestellte Awk-Skript

tag-icon • tag-icon shell-script awk
Bitte erläutern Sie das unten bereitgestellte Awk-Skript

Kann mir bitte jemand das unten geschriebene AWK-Skript Schritt für Schritt erklären.

Ich habe den folgenden Code in mein Skript geschrieben, um die Flatfile-Daten zu formatieren. Ich wollte es nur verstehen, damit ich es wiederverwenden kann – ich bin kein Unix-Typ, aber mir wurde eine Aufgabe zugewiesen. Bitte helfen Sie!

awk -vsep=$SEPARATOR 'NR>2{if(NF){if(!s){gsub(" *"sep"[ \t]*",sep);printf "%d%s\n",NR-2,$0}}else s=1}' file_name > new_file

 # where $SEPARATOR = ';'

Dank im Voraus.

Antwort1

Die Befehlszeilenoption -vsep=$SEPERATORsetzt eine Awk-Variable sep(die beim Suchen/Ersetzen verwendet wird) auf den von Ihnen angegebenen Wert, ;in Ihrem Fall.

# NR = Number of current Record, or line number
# Skip the first line
if ( NR > 2 ) {

  # NF = Number of fields in the current record
  # If the line contains something other than a blank line or the 
  # awk field separator characters (whitespace by default)
  if ( NF ) {

    # If we have not seen a blank line (script flag s)
    if ( !s ) {

      # Search the current line repeatedly (gsub) for any number of spaces (" *") 
      # before a ";" then any number of spaces or tabs ([ \t]*) after the `;`
      # and replace it all with just a ";"
      gsub( " *"sep"[ \t]*", sep );

      # Print the line number, 0 based (NR-2) as a signed decimal integer (`%d`)
      # then the complete line ($0) followed by a new line character (\n)
      printf "%d%s\n", NR-2, $0;
    }

  } else { 

    # Set the "seen a blank line" flag
    s = 1
  }

}

file_name > new_fileschreibt die Ausgabe in eine neue Datei namensnew_file

Übrigens: Wenn Sie das Skript wie folgt strukturieren, ist es viel leichter zu lesen und schneller, wenn nach einer Leerzeile große Datenmengen auftreten.

awk -vsep=$SEPERATOR '{

# Skip the first line
if (NR == 1) { next; }

# Stop processing if we see a blank line
if (NF == 0) { exit; }

# Remove spaces before and spaces/tabs after separator
gsub( " *"sep"[ \t]*", sep );

# Print the line with a record number starting from 0
printf "%d%s\n", NR-2, $0;

}' file_name > new_file

verwandte Informationen