☰

Signaturrichtlinien in Exchange 2003 mithilfe von Active Directory-Feldern erzwingen

tag-icon • tag-icon active-directory exchange outlook
Signaturrichtlinien in Exchange 2003 mithilfe von Active Directory-Feldern erzwingen

Unsere Organisation hat entschieden, dass sie für alle Benutzer einen Standardsignaturblock benötigt, der auf deren Namen, Berufsbezeichnung, Kontaktdaten und Bürostandort basiert und alle im Active Directory gespeichert sind.

Hat jemand eine gute Lösung zum automatischen Generieren von Outlook-/Exchange 2003-Signaturen basierend auf Active Directory-Feldern gefunden?

Antwort1

Ich bin langjähriger Kunde und Fan vonExclaimer Mail-Dienstprogramme.

Es befindet sich auf Ihrem Exchange-Server und verfügt über zahlreiche anpassbare Regeln, die bestimmen, ob Briefpapier verwendet wird oder nicht. Ich habe es so eingerichtet, dass es allen extern versendeten E-Mails unser Firmenlogo oben hinzufügt und unten den Namen, die Berufsbezeichnung und verschiedene Telefonnummern der Personen – alles aus Active Directory.

Ich habe den Support nur einmal in Anspruch genommen, aber sie waren sehr freundlich, kompetent und haben mein Problem sehr schnell gelöst.

Antwort2

Ich hatte viel Glück mit einem Skript, das ich geschrieben habe. Es schreibt aus verschiedenen AD-Feldern in ein unsichtbares Word-Dokument und kopiert es dann als Standard- und Antwortsignatur in Outlook 2007.

Ich habe es aufgegeben, es bei jeder Anmeldung automatisch auszuführen. Sehr selten hatte ich Probleme bei der ersten Anmeldung eines Benutzers an einem Computer, wo Outlook noch nicht geöffnet werden konnte, ohne den Assistenten zu durchlaufen. Ab sofort ist es ein GPO, das einfach eine Verknüpfung mit dem Namen „E-Mail-Signatur zurücksetzen“ auf die Desktops der Benutzer sendet. Dies ermöglicht es Benutzern auch, nicht standardmäßige Signaturen zu haben, ohne dass diese jedes Mal überschrieben werden.

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

Wenn Du Fragen hast, lass es mich einfach wissen!

verwandte Informationen