☰

Reemplace el archivo delimitado por comas con barra vertical, pero no elimine comas ni comillas, etc. dentro del campo calificador de texto; sin embargo, elimine el calificador de texto.

tag-icon • tag-icon shell-script sed regular-expression replace
Reemplace el archivo delimitado por comas con barra vertical, pero no elimine comas ni comillas, etc. dentro del campo calificador de texto; sin embargo, elimine el calificador de texto.

Mi archivo es un archivo delimitado por comas y el calificador de texto es ~, pero mi requisito es buscar y reemplazar el archivo delimitado por comas con un archivo delimitado por |(tubería) y eliminar el calificador de texto ~ sin nada; sin embargo, no debo eliminar las comillas ni las comillas dobles ni cualquier carácter especial dentro de los datos presentes en el calificador de texto. por ejemplo: ~abc",~ lo necesito como abc",

A continuación se muestra el contenido de mi archivo fuente y la forma en que espero que sea el archivo de salida o manipulado.

Archivo fuente:

364034,2015652205,26722,2015,4,~C25753-4~,~TC25753,~,~2WD Double Cab 144.2" SLT,~,~Y~,40506.16,43555.00,1095.00,~043,005,006,007,003,008,016,041,012,029,068,027,028,033~,3,~2WD Double Cab 144.2"~,~SLT~,6,4,~N~,~S~,~N~,~S~,~N~,~N~,~N~,~~,~ ~,~Confirmed~,~w2015k65m22t5~,~Sierra 2500HD~,~Double Cab Standard Box 2-Wheel Drive SLT~,~Rear Wheel Drive~,~Extended Cab Pickup - Standard Bed~

Después de la limpieza necesito el archivo como este:

364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043|005|006|007|003|008|016|041|012|029|068|027|028|033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

Probé sed -i -e con múltiples opciones pero el resultado no es 100% correcto.

Intenté seguirlo pero no me da el resultado correcto que quería.

sed -i -e 's/,~/|/g' file_name
sed -i -e 's/~,/|/g' file_name
sed -i -e 's/~//g' file_name
sed -i -e 's/\([0-9],[0-9]\)/|/g' file_name
sed -i -e 's/\r//g' file_name

Respuesta1

ESC=$(printf '\033')
RED="${ESC}[0;31m"
 NC="${ESC}[0m"

sed -e '
   /./!b
   /[^[:space:]]/!b

   s/.*/\
&,/

   :loop
      h
      s/\(\n\),/|\1/;                                                  # An empty field
      s/\(\n\)\([+-]\{0,1\}[.][0-9]\{1,\}\),/\2|\1/;                   # +-.NNN
      s/\(\n\)\([+-]\{0,1\}[0-9]\{1,\}\([.][0-9]*\)\{0,1\}\),/\2|\1/;  # +-NNN.MMM +-NNN. +-NNN
      s/\(\n\)~\([0-9][0-9]*\),/\2|\1/;                                # ~NNN
      s/\(\n\)\([0-9][0-9]*\)~,/\2|\1/;                                # NNN~
      s/\(\n\)~\([^~]*\)~,/\2|\1/;                                     # ~...~
      x;G
      /^\(.*\)\n\1$/{
         g;'"s/\n\([^,]*\)/${RED}\1${NC}/"'
         i\
***'"${RED}ERROR${NC}"'*** Unable to process the field shown colored.\
\
Cause of error: What this means is that this particular field is not \
\
           Fix: You should add to the sed code in the :loop label to \
                digest the able to be processed by the sed code as it stands.\
\
The record with the offending field shown colored red:\

         q
      }
      g; # all clear: recover and carry on...
   /\n$/!bloop

   s/..$//
' csv.data

Laboral

  • Basamos la solución en los distintos tipos de campos.
  • Salta líneas vacías o en blanco.
  • Agregue un "," para simplificar la expresión regular utilizada, la quitaremos al final.
  • Para poner la bola en marcha colocamos un marcador, \n, al principio de la línea. Este marcador viajará de izquierda a derecha, saltando un campo procesado a la vez.
  • La acción comienza en el do-whilebucle, en cuyo cuerpo procesamos un campo a la vez. El inicio del campo está señalado \ny procesamos las distintas variedades de campos que pueden ocurrir. Cada vez, llevamos el campo procesado a la izquierda de \ny lo reemplazamos ,por un |.
  • El bucle se detiene cuando el marcador \nllega al final de la línea /\n$/y luego retiramos el marcador y el muñeco que ,habíamos colocado al principio.

Resultados

364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043|005|006|007|003|008|016|041|012|029|068|027|028|033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

Respuesta2

Sugeriría utilizar un analizador CSV dedicado como el de Perl.Texto::CSV

perl -MText::CSV -lne '
    BEGIN{ $csv = Text::CSV->new({ quote_char => "~" , escape_char => "~" , allow_whitespace => 1}) } 
    print join "|", $csv->fields() if $csv->parse($_)
  ' file_name
364034|2015652205|26722|2015|4|C25753-4|TC25753,|2WD Double Cab 144.2" SLT,|Y|40506.16|43555.00|1095.00|043,005,006,007,003,008,016,041,012,029,068,027,028,033|3|2WD Double Cab 144.2"|SLT|6|4|N|S|N|S|N|N|N|| |Confirmed|w2015k65m22t5|Sierra 2500HD|Double Cab Standard Box 2-Wheel Drive SLT|Rear Wheel Drive|Extended Cab Pickup - Standard Bed

información relacionada