Este script por lotes finaliza cuando %CHECKCONTINUE%se le da un valor nulo al no ingresar nada en la línea 13 ( SET /p CHECKCONTINUE=Okay to continue? (y/n):), ¿a qué se debe esto?
@ECHO OFF
SETLOCAL
TITLE Registry restore script
REM Restores registry settings and disables the cloud
SET %CHECKCONTINUE%=
:listaction
ECHO I'm about to...
ECHO 1.) Remove the registry data that specifies settings for TF2
ECHO 2.) Forcibly disable Steam Cloud.
ECHO.
SET /p CHECKCONTINUE=Okay to continue? (y/n):
REM No?
IF %CHECKCONTINUE%==n GOTO exit
IF %CHECKCONTINUE%==no GOTO exit
REM Yes?
IF %CHECKCONTINUE%==y GOTO start
IF %CHECKCONTINUE%==yes GOTO start
REM Did they put something else?
IF DEFINED %CHECKCONTINUE% GOTO loop-notvalid
REM Did they not put anything at all?
IF NOT DEFINED %CHECKCONTINUE% GOTO loop-noreply
:start
REM Delete application specific data
REG DELETE HKEY_CURRENT_USER\Software\Valve\Source\tf\Settings /f
REG DELETE HKEY_CURRENT_USER\Software\Valve\Steam\Apps\440 /f
REM Disable Steam Cloud for TF2
REG ADD HKEY_CURRENT_USER\Software\Valve\Steam\Apps\440 /v Cloud /t REG_DWORD /d "0x0" /f
:exit
ENDLOCAL
EXIT
:loop-notvalid
ECHO.
ECHO That's not a valid reply. Try again.
ECHO.
SET %CHECKCONTINUE%=
GOTO listaction
:loop-noreply
ECHO.
ECHO You must enter a reply.
ECHO.
SET %CHECKCONTINUE%=
GOTO listaction
Respuesta1
Primero, en varias líneas tienes:
SET %CHECKCONTINUE%=
Esto no modifica CHECKCONTINUEpero usa suvalorcomo nombre de la variable.
Cámbielo a:
SET CHECKCONTINUE=
También sería mejor si lo movieras inmediatamente arriba set /p ...; de esta manera solo lo necesitarías una vez.
if definedtambién solo toma un nombre de variable, por lo que en lugar de
IF DEFINED %CHECKCONTINUE% GOTO loop-notvalid
Deberías usar:
IF DEFINED CHECKCONTINUE GOTO loop-notvalid
Lo mismo se aplica a esta línea:
IF NOT DEFINED %CHECKCONTINUE% GOTO loop-noreply
Sin embargo, se puede abreviar a:
GOTO loop-noreply
Si la variable estuviera definida, la ejecución nunca llegaría a esta línea de todos modos ( if defined ...arriba)
Así lo hubiera escrito yo:
@echo off & setlocal
title Registry restore script
:: Restores registry settings and disables the Cloud
:menu
echo I'm about to...
echo 1) Remove the registry data that specifies settings for TF2
echo 2) Forcibly disable Steam Cloud.
echo.
set check=
set /p check=Okay to continue? (y/n)
:: /i means case-insensitive comparison
if /i %check%==y goto :start
if /i %check%==yes goto :start
if /i %check%==n goto :EOF
if /i %check%==no goto :EOF
:: On empty response, pick the safest option as default
if not defined check goto :EOF
goto :loop-invalid
:start
:: Delete application specific data
reg delete HKCU\Software\Valve\Source\tf\Settings /f
reg delete HKCU\Software\Valve\Steam\Apps\440 /f
:: Disable Steam Cloud for TF2
reg add HKCU\Software\Valve\Steam\Apps\440 /v Cloud /t REG_DWORD /d "0x0" /f
:loop-invalid
echo.
echo Not a valid answer.
goto :menu
Respuesta2
Ampliando la gran respuesta de Gragraty:
Primero, para responder a su pregunta: ¿Por qué finaliza el script por lotes cuando a %CHECKCONTINUE% se le asigna un valor nulo?
El problema es que, en la línea 16, haces esto:
if %CHECKCONTINUE%==n GOTO exit
Como CHECKCONTINUEestá "indefinido", se evalúa como una cadena "vacía", por lo que la declaración en la línea 16 en realidad hace lo siguiente:
if ==n GOTO exit
Esta es una declaración no válida porque no hay nada en el lado izquierdo del archivo "==". Entonces, el script por lotes finaliza cuando intenta ejecutar una declaración con formato incorrecto:
C:\>script.cmd
I'm about to...
1.) Remove the registry data that specifies settings for TF2
2.) Forcibly disable Steam Cloud.
Okay to continue? (y/n): <ENTER key pressed>
GOTO was unexpected at this time.
C:\>
Tendrías un problema similar si alguien escribe algo que contenga un espacio:
C:\>script.cmd
I'm about to...
1.) Remove the registry data that specifies settings for TF2
2.) Forcibly disable Steam Cloud.
Okay to continue? (y/n): Yes please
please==n was unexpected at this time.
C:\>
Para solucionar este problema, debe utilizar comillas dobles alrededor de términos como este:
if "%CHECKCONTINUE%"=="n" GOTO :exit
Esto es necesario si las variables utilizadas pudieran estar "vacías" o si pudieran tener espacios en blanco incrustados, pero es una buena idea usar siempre comillas dobles al evaluar con "==".
Nota: Algunos errores (como el de arriba con "if"y "=="son errores "fatales" que harán que la ejecución del script por lotes se detenga inmediatamente. Otros errores (como el de abajo con "set") son errores "no fatales". "Errores fatales", la declaración con el error NO se ejecuta, se muestra un mensaje de error y el script por lotes continúa ejecutándose a partir de la siguiente declaración.
A continuación, como señaló Grawity sobre esta línea:
set %CHECKCONTINUE%=
Esto no modifica CHECKCONTINUE pero usa su valor como nombre de la variable.
Nuevamente, si CHECKCONTINUEfuera "indefinido", se evaluaría como una cadena "vacía", por lo que la declaración en realidad funciona:
set =
Esta también es una declaración no válida porque no hay nada en el lado izquierdo del archivo "=".
Y estas líneas:
if defined %CHECKCONTINUE% GOTO loop-notvalid
if not defined %CHECKCONTINUE% GOTO loop-noreply
"if defined"(y "if not defined") espera un nombre de variable, no el valor de una variable. Si CHECKCONTINUEno estuviera definido, %CHECKCONTINUE%se evaluaría como una cadena vacía y estas declaraciones en realidad serían:
if defined GOTO loop-notvalid
if not defined GOTO loop-noreply
Aquí, "if defined"(y "if not defined") comprobará si una variable nombrada GOTOestá definida o no.
Además, para estas 3 líneas, if CHECKCONTINUEestaba realmente definido "set"y "if defined"operaría en "value"la variable, en lugar de en "name"la variable misma. Entonces, si CHECKCONTINUEya tenía un valor de "y", entonces:
set %CHECKCONTINUE%=
if defined %CHECKCONTINUE% goto loop-notvalid
if not defined %CHECKCONTINUE% goto loop-noreply
en realidad sería visto como:
set y=
if defined y goto loop-notvalid
if not defined y goto loop-noreply
Ejemplo "script.cmd":
@set "CHECKCONTINUE="
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" (undefined/empty).
@rem ## 05: set %CHECKCONTINUE%=
set %CHECKCONTINUE%=
@echo This doesn't set the value of of the variable named "CHECKCONTINUE".
@echo Since no variable name is actually specified, it is an error.
@set "CHECKCONTINUE=yes"
@set "yes=something"
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" and the value of the variable named "yes"="%yes%"
@rem ## 17: set %CHECKCONTINUE%=
set %CHECKCONTINUE%=
@echo This doesn't set the value of the variable named "CHECKCONTINUE".
@echo Since CHECKCONTINUE="%CHECKCONTINUE%", it sets the value of the variable named
@echo "%CHECKCONTINUE%". No error is shown because the statement is valid.
@echo It could have been a problem (well, at least a big annoyance) if
@echo CHECKCONTINUE had the value: "path". The statement
@echo should be: set "CHECKCONTINUE="
@rem ## 27: echo CHECKCONTINUE still has the value: "%CHECKCONTINUE%"
@echo CHECKCONTINUE still has the value: "%CHECKCONTINUE%"
@rem ## 30: echo and the variable named "%CHECKCONTINUE%" is now empty="%yes%"
@echo and the variable named "%CHECKCONTINUE%" is now empty="%yes%"
@set "yes="
@set "CHECKCONTINUE="
@set "echo=something"
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" (undefined) and the value of the variable
@rem ## named "echo"="%echo%".
@rem ## 41: if defined %CHECKCONTINUE% echo Variable is defined.
if defined %CHECKCONTINUE% echo Variable is defined.
@echo This doesn't check if the variable named "CHECKCONTINUE" is defined.
@echo Since it's "empty", it is skipped (well, there is nothing there to
@echo "skip") and "if defined" is checking the next word (which is "echo").
@echo What's left is: if defined echo Variable is defined.
@echo So, it checks if a variable named "echo" is defined (which it is).
@echo Since "if defined" has checked a variable named "echo", it then tries
@echo to execute the rest of the line starting with the word "Variable",
@echo as a command. This fails and is an error. The statement
@echo should be: if defined CHECKCONTINUE echo Variable is defined.
@set "echo="
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" (undefined) and "echo"="%echo%" (undefined).
@rem ## 59: if not defined %CHECKCONTINUE% echo The-variable-is-not-defined.
if not defined %CHECKCONTINUE% echo The-variable-is-not-defined.
@echo Similar: Since "if not defined" has checked a variable named "echo"
@echo (which is "undefined"), it then tries to execute the rest of the
@echo line: "The-variable-is-not-defined." as a command. This fails and is
@echo an error. The statement
@echo should be: if not defined CHECKCONTINUE echo The-variable-is-not-defined.
@set "echo=something"
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" (undefined) and "echo"="%echo%".
@rem ## 73: if defined %CHECKCONTINUE% echo Verify this.
if defined %CHECKCONTINUE% echo Verify this.
@echo Again, similar: Since "if defined" has checked a variable named
@echo "echo", it then tries to execute the rest of the line starting with
@echo the word: "Verify" as a command. This happens to be a valid command
@echo but it also fails because of an incorrect parameter for the command.
@echo The statement should be: if defined CHECKCONTINUE echo Verify this.
@set "echo="
@set "CHECKCONTINUE=yes"
@set "yes="
@rem ## CHECKCONTINUE="%CHECKCONTINUE%" and the variable named "yes"="%yes%" (undefined).
@rem ## 90: if not defined %CHECKCONTINUE% echo CHECKCONTINUE is not defined.
if not defined %CHECKCONTINUE% echo CHECKCONTINUE is not defined.
@echo Here "CHECKCONTINUE" is defined, but "if not defined" still doesn't
@echo check if the variable named "CHECKCONTINUE" is defined. Since
@echo CHECKCONTINUE has a value of "%CHECKCONTINUE%", "if not defined" is
@echo checking if a variable named "%CHECKCONTINUE%" is defined (which it isn't).
@echo This causes "if not defined" to proceed and echo the message when
@echo that's probably not what was intended. The statement
@echo should be: if not defined CHECKCONTINUE echo CHECKCONTINUE is not defined.
Al ejecutar "script.cmd" obtendrías:
## CHECKCONTINUE="" (undefined/empty).
## 05: set %CHECKCONTINUE%=
C:\>set =
The syntax of the command is incorrect.
This doesn't set the value of of the variable named "CHECKCONTINUE".
Since no variable name is actually specified, it is an error.
## CHECKCONTINUE="yes" and the value of the variable named "yes"="something"
## 17: set %CHECKCONTINUE%=
C:\>set yes=
This doesn't set the value of the variable named "CHECKCONTINUE".
Since CHECKCONTINUE="yes", it sets the value of the variable named
"yes". No error is shown because the statement is valid.
It could have been a problem (well, at least a big annoyance) if
CHECKCONTINUE had the value: "path". The statement
should be: set "CHECKCONTINUE="
## 27: echo CHECKCONTINUE still has the value: "%CHECKCONTINUE%"
CHECKCONTINUE still has the value: "yes"
## 30: echo and the variable named "yes" is now empty="%yes%"
and the variable named "yes" is now empty=""
## CHECKCONTINUE="" (undefined) and the value of the variable
## named "echo"="something".
## 41: if defined %CHECKCONTINUE% echo Variable is defined.
C:\>if defined echo Variable is defined.
'Variable' is not recognized as an internal or external command,
operable program or batch file.
This doesn't check if the variable named "CHECKCONTINUE" is defined.
Since it's "empty", it is skipped (well, there is nothing there to
"skip") and "if defined" is checking the next word (which is "echo").
What's left is: if defined echo Variable is defined.
So, it checks if a variable named "echo" is defined (which it is).
Since "if defined" has checked a variable named "echo", it then tries
to execute the rest of the line starting with the word "Variable",
as a command. This fails and is an error. The statement
should be: if defined CHECKCONTINUE echo Variable is defined.
## CHECKCONTINUE="" (undefined) and "echo"="" (undefined).
## 59: if not defined %CHECKCONTINUE% echo The-variable-is-not-defined.
C:\>if not defined echo The-variable-is-not-defined.
'The-variable-is-not-defined.' is not recognized as an internal or external command,
operable program or batch file.
Similar: Since "if not defined" has checked a variable named "echo"
(which is "undefined"), it then tries to execute the rest of the
line: "The-variable-is-not-defined." as a command. This fails and is
an error. The statement
should be: if not defined CHECKCONTINUE echo The-variable-is-not-defined.
## CHECKCONTINUE="" (undefined) and "echo"="something".
## 73: if defined %CHECKCONTINUE% echo Verify this.
C:\>if defined echo Verify this.
An incorrect parameter was
entered for the command.
Again, similar: Since "if defined" has checked a variable named
"echo", it then tries to execute the rest of the line starting with
the word: "Verify" as a command. This happens to be a valid command
but it also fails because of an incorrect parameter for the command.
The statement should be: if defined CHECKCONTINUE echo Verify this.
## CHECKCONTINUE="yes" and the variable named "yes"="" (undefined).
## 90: if not defined %CHECKCONTINUE% echo CHECKCONTINUE is not defined.
C:\>if not defined yes echo CHECKCONTINUE is not defined.
CHECKCONTINUE is not defined.
Here "CHECKCONTINUE" is defined, but "if not defined" still doesn't
check if the variable named "CHECKCONTINUE" is defined. Since
CHECKCONTINUE has a value of "yes", "if not defined" is
checking if a variable named "yes" is defined (which it isn't).
This causes "if not defined" to proceed and echo the message when
that's probably not what was intended. The statement
should be: if not defined CHECKCONTINUE echo CHECKCONTINUE is not defined.
Además, como alternativa a "set /p", puedes utilizar "choice":
@echo off
title Registry restore script
rem Restores registry settings and disables the cloud
rem "quotes" around variable name and value for set visibly shows what
rem the variable is being set to and prevents accidentally including
rem trailing whitespace in the variable's value.
set "CHECKCONTINUE="
:listaction
echo I'm about to...
echo 1.) Remove the registry data that specifies settings for TF2
echo 2.) Forcibly disable Steam Cloud.
echo.
choice /c yn /M "Okay to continue"
set "CHECKCONTINUE=%errorlevel%"
if %CHECKCONTINUE% EQU 1 @echo Pressed Y && goto :start
if %CHECKCONTINUE% EQU 2 @echo Pressed N && goto :exit
if %CHECKCONTINUE% EQU 0 @echo Pressed Ctrl-C+n
@echo.
@echo Terminate batch job cancelled. You must enter a reply. Press n to exit.
@echo.
goto :listaction
rem The remainder of your code goes here ...
Nota: el código en la etiqueta: "loop-notvalid"no es necesario porque "elección" no aceptará respuestas indefinidas (sí/no).
Además, la única forma de obtener una respuesta "vacía" del comando "elección" es si el usuario presiona "Ctrl-C" para finalizar el trabajo por lotes y luego ingresa N (No) en el campo "Terminar trabajo por lotes (Y/ NORTE)?" mensaje, indicando que NO quieren salir. El código anterior capta eso e imprime un mensaje y luego salta (ir a) a la etiqueta ":listaction" para volver a avisar al usuario, por lo que tampoco necesita el código en la etiqueta "loop-noreply".
No es necesario "restablecer" el nivel de error ya que el comando de elección se encarga de ello. Y no es necesario borrar la CHECKCONTINUEvariable porque siempre se establece igual a antes de que se examine %errorlevel%el valor de .CHECKCONTINUE
De forma predeterminada, la opción no distingue entre mayúsculas y minúsculas, por lo que presionar "Y" o "N" es lo mismo que presionar "y" o "n". Este comportamiento se puede cambiar especificando /csen la línea de comando de elección.