☰

¿Algún ajuste de Spotify con el método abreviado de teclado para destacar las pistas?

tag-icon • tag-icon windows-7 keyboard-shortcuts spotify
¿Algún ajuste de Spotify con el método abreviado de teclado para destacar las pistas?

Soy un suscriptor premium de Spotify y un fanático obsesivo de la productividad.

Una cosa que realmente me molesta es que no hay un método abreviado de teclado para destacar una pista (es decir, agregar una pista a favoritos). Me gusta dejar la radio de Spotify encendida mientras trabajo y de vez en cuando tengo que desplazarme y hacer clic derecho en la pista y luego seleccionar 'Estrella' cada vez que escucho una canción que realmente me gusta.

¿Existen ajustes/complementos de Spotify que me permitan destacar pistas con un atajo de teclado?

Respuesta1

Claro, usaAutoHotkey!

Una vez que lo tengas instalado, pon esto en tu archivo AutoHotkey.ahk:

#*::
WinWait, Spotify, 
IfWinNotActive, Spotify, , WinActivate, Spotify, 
WinWaitActive, Spotify, 
MouseClick, left,  79,  90
Sleep, 100
MouseClick, left,  256,  152
Sleep, 100
return

Esto agrega una tecla de acceso rápido Win+Asterisco que destacará la pista que se está reproduciendo.

También te puede interesar otrosAtajos de Spotifypara AutoHotkey.

Respuesta2

Probé el otro atajo de Autohotkey y no funcionó para mí (simplemente cambié a Spotify e hice clic en dos puntos muertos). Ideé lo siguiente, que funciona siempre y cuando tengas seleccionada la opción "Ilustración grande en reproducción":

CoordMode, Mouse, Relative
;star currently playing
+^l::
SpotifyWinHeight = 1050 ;set to 1080 - 30 for small taskbar size, just in case WinGetPos doesn't work for some reason
WinGetActiveTitle, CurWindow
WinActivate Spotify
WinWaitActive Spotify
WinGetPos,  ,  ,  , SpotifyWinHeight, Spotify
;          X  Y  W  H, we don't care about anything but height
RightClickTarget := SpotifyWinHeight - 250
ContextMenuTarget := RightClickTarget + 110
MouseMove, 100, %RightClickTarget%
Click Right
Sleep, 50
MouseMove, 180, %ContextMenuTarget%
Sleep, 50
Click
WinActivate %CurWindow%
return

Hace lo siguiente:

  • Ventana de tiendas actualmente activas
  • Activa Spotify
  • Calcula las compensaciones al hacer clic en la carátula del álbum en relación con la ventana de Spotify
  • Destaca lo que se está reproduciendo actualmente (haciendo clic con el botón derecho en la ilustración, haciendo clic con el botón izquierdo en Estrella)
  • Restaura cualquier ventana que estuviera activa antes de todo esto.

No es perfecto (probablemente no estarás contento si por alguna razón tienes Spotify colgando mayormente de tu pantalla a la derecha), pero hace el trabajo en la mayoría de los casos.

Respuesta3

Destacado ya no existe.

Ven aquípara las preguntas y respuestas actualizadas.

Antigua respuesta a continuación aquí...

Aquí está otroAutoHotkeysolución. Hay comentarios liberales. Además, la documentación y los foros de AutoHotkey son excelentes lugares para aprender si lo desea.

Al presionar Control+Shift+* se destacará la canción activa.
Una característica clave de este script es que verifica si la canción ya está destacada y la deja en paz si es así.

^+*::
spotify = ahk_class SpotifyMainWindow
IfWinExist, %spotify%
{
;Store active window and mouse position.
WinGetActiveTitle, activeWindow
MouseGetPos x, y, winID

;Activate Spotify.
WinActivate %spotify%
WinWaitActive %spotify%

;Right click near the song title in the "Now Playing" box.
WinGetPos,  ,  ,  , spotifyHeight, %spotify%
MouseClick, Right, 100, spotifyHeight - 70, 1, 0

;Get the contents of the context menu.
WinWait, ahk_class #32768
SendMessage, 0x1E1      ; MN_GETHMENU
allContextMenuInfo := ErrorLevel

;The "Star" command is the 5th menu item.
;If the song is Unstarred the text is Star, and vice versa. But sometimes some wierd characters are included.
;The only reliable way I found is to check if the first letter is S.
menuText_StarUnstar := GetContextMenuItemText(allContextMenuInfo, 5)
StringGetPos, positionOfS, menuText_StarUnstar, S

;If S is the first letter, star the song.
notStarred := (%positionOfS% = 0)
If notStarred {
    ;Arrow down to the Star menu item and press enter.
    Send {Down}{Down}{Down}{Down}{Down}{Enter}
} Else {
    ;Just close the context menu.
    Send {Escape}
}

;Restore original window and mouse position.
WinActivate ahk_id %winID%
MouseMove %x%, %y%
}

Return

;Conext menu helper function.
GetContextMenuItemText(hMenu, nPos)
{
length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "UInt", 0 ; NULL
        , "Int", 0  ; Get length
        , "UInt", 0x0400)   ; MF_BYPOSITION
    VarSetCapacity(lpString, length + 1)
    length := DllCall("GetMenuString"
        , "UInt", hMenu
        , "UInt", nPos
        , "Str", lpString
        , "Int", length + 1
        , "UInt", 0x0400)
return lpString
}

Respuesta4

También puedes probar miAplicación Spotify, centelleo, que es una solución independiente del diseño de la plataforma y la GUI para mirar canciones de Spotify con un solo clic.

información relacionada